Пример создания инфраструктуры с балансировщиком нагрузки

Пример создания инфраструктуры с облачным балансировщиком нагрузки

Мы рекомендуем создавать ресурсы по порядку. Если вы единовременно создаете все ресурсы, которые описаны в конфигурационном файле, может возникнуть ошибка — Terraform создает ресурсы независимо от порядка, в котором они перечислены в файле.

Конфигурационные файлы⁠

Пример файла для настройки провайдеров

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "6.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Пример файла для создания инфраструктуры с облачным балансировщиком нагрузки

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = openstack_networking_network_v2.network_1.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }
}

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.ru-9a"
  availability_zone    = "ru-9a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = "4011"
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

resource "openstack_lb_loadbalancer_v2" "load_balancer_1" {
  name          = "load-balancer"
  vip_subnet_id = openstack_networking_subnet_v2.subnet_1.id
  flavor_id     = "ac18763b-1fc5-457d-9fa7-b0d339ffb336"
}

resource "openstack_lb_listener_v2" "listener_1" {
  name            = "listener"
  protocol        = "TCP"
  protocol_port   = "80"
  loadbalancer_id = openstack_lb_loadbalancer_v2.load_balancer_1.id
}

resource "openstack_lb_pool_v2" "pool_1" {
  name        = "pool"
  protocol    = "PROXY"
  lb_method   = "ROUND_ROBIN"
  listener_id = openstack_lb_listener_v2.listener_1.id
}

resource "openstack_lb_member_v2" "member_1" {
  name          = "member"
  subnet_id     = openstack_networking_subnet_v2.subnet_1.id
  pool_id       = openstack_lb_pool_v2.pool_1.id
  address       = "192.168.199.4"
  protocol_port = "80"
}

resource "openstack_lb_monitor_v2" "monitor_1" {
  name        = "monitor"
  pool_id     = openstack_lb_pool_v2.pool_1.id
  type        = "HTTP"
  delay       = "10"
  timeout     = "4"
  max_retries = "5"
}

resource "openstack_networking_floatingip_v2" "floatingip_1" {
  pool    = "external-network"
  port_id = openstack_lb_loadbalancer_v2.load_balancer_1.vip_port_id
}

output "public_ip_address" {
  value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
}

1. Опционально: настроить провайдеры⁠

Если вы настроили провайдеры Selectel и OpenStack, пропустите этот шаг.

Убедитесь, что в панели управления вы создали сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей.
Создайте директорию для хранения конфигурационных файлов и отдельный файл с расширением .tf для настройки провайдеров.
В файл для настройки провайдеров добавьте провайдеры Selectel и OpenStack:
```
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "6.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Здесь version — версии провайдеров. Актуальную версию можно посмотреть в документации Selectel (в Terraform Registry и GitHub) и OpenStack (в Terraform Registry и GitHub).

Подробнее о продуктах, услугах и сервисах, которыми можно управлять с помощью провайдеров, в инструкции Провайдеры Selectel и OpenStack.
Инициализируйте провайдер Selectel:
```
provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
}
```
Здесь:
- domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
- username — имя сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей. Можно посмотреть в панели управления: раздел Управление доступом → Управление пользователями → вкладка Сервисные пользователи (раздел доступен только Владельцу аккаунта и Администратору пользователей);
- password — пароль сервисного пользователя. Можно посмотреть при создании пользователя или изменить на новый.
Создайте проект:
```
resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}
```
Посмотрите подробное описание ресурса selectel_vpc_project_v2.
Создайте сервисного пользователя для доступа к проекту и назначьте ему роль Администратор проекта:
```
resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}
```
Здесь:
- username — имя пользователя;
- password — пароль пользователя. Пароль должен быть не короче восьми символов и содержать латинские буквы разных регистров и цифры;
- project_id — ID проекта. Можно посмотреть в панели управления: раздел Облачная платформа → откройте меню проектов (название текущего проекта) → в строке нужного проекта нажмите .
Посмотрите подробное описание ресурса selectel_iam_serviceuser_v1.
Инициализируйте провайдер OpenStack:
```
provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}
```
Здесь:
- domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
- region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.
Если одновременно с настройкой провайдеров вы создаете ресурсы, то для ресурсов OpenStack добавьте аргумент depends_on. Например, для ресурса openstack_networking_network_v2:
```
resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    selectel_vpc_project_v2.project_1,
    selectel_iam_serviceuser_v1.serviceuser_1
  ]
}
```
Опционально: если вы хотите использовать зеркало, создайте отдельный конфигурационный файл Terraform CLI и добавьте в него блок:
```
provider_installation {
  network_mirror {
    url = "https://tf-proxy.selectel.ru/mirror/v1/"
    include = ["registry.terraform.io/*/*"]
  }
  direct {
    exclude = ["registry.terraform.io/*/*"]
  }
}
```
Подробнее о настройках зеркал в инструкции CLI Configuration File документации HashiCorp.
Откройте CLI.
Инициализируйте конфигурацию Terraform в директории:
```
terraform init
```
Проверьте, что конфигурационные файлы составлены без ошибок:
```
terraform validate
```
Отформатируйте конфигурационные файлы:
```
terraform fmt
```
Проверьте, какие ресурсы будут созданы:
```
terraform plan
```
Примените изменения и создайте ресурсы:
```
terraform apply
```
Подтвердите создание — введите yes и нажмите Enter. Созданные ресурсы отобразятся в панели управления.
Если для создания ресурсов оказалось недостаточно квот, увеличьте квоты.

2. Создать приватную сеть и подсеть⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Здесь cidr — CIDR приватной подсети, например 192.168.199.0/24.

Посмотрите подробное описание ресурсов:

3. Создать облачный роутер, подключенный к внешней сети⁠

Облачный роутер, подключенный к внешней сети, выполняет функцию 1:1 NAT для доступа из приватной сети в интернет через публичный IP-адрес роутера.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

Посмотрите подробное описание ресурсов:

4. Создать облачный сервер⁠

1. Создать пару SSH-ключей⁠

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

Здесь public_key — путь до публичного SSH-ключа. Если SSH-ключи не созданы, сгенерируйте их.

Посмотрите подробное описание ресурса selectel_vpc_keypair_v2.

2. Создать порт для облачного сервера⁠

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = openstack_networking_network_v2.network_1.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }
}

Посмотрите подробное описание ресурса openstack_networking_port_v2.

3. Получить образ⁠

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

Посмотрите подробное описание источника данных openstack_images_image_v2.

4. Создать загрузочный сетевой диск⁠

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.ru-9a"
  availability_zone    = "ru-9a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

Здесь:

size — размер диска в ГБ. Учитывайте лимиты сетевых дисков на максимальный размер;
volume_type — ID или имя типа сетевого диска. Например, fast.ru-9a — имя для создания сетевого диска с типом SSD Быстрый в сегменте пула ru-9a. Список типов можно посмотреть в таблице Список типов сетевого диска во всех сегментах пула;
availability_zone — сегмент пула, в котором будет создан сетевой диск, например ru-9a. Список доступных сегментов пула можно посмотреть в инструкции Матрицы доступности.

Посмотрите подробное описание ресурса openstack_blockstorage_volume_v3.

5. Создать облачный сервер⁠

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = "4011"
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Здесь:

availability_zone — сегмент пула, в котором будет создан облачный сервер, например ru-9a. Список доступных сегментов пула можно посмотреть в инструкции Матрицы доступности;
flavor_id — ID флейвора. Флейворы соответствуют конфигурациям облачного сервера и определяют количество vCPU, RAM и размер локального диска (опционально) сервера. Можно использовать флейворы фиксированных конфигураций. Например, 4011 — ID для создания сервера с фиксированной конфигурацией линейки Memory Line с 2 vCPU, 16 ГБ RAM в пуле ru-9. Список флейворов можно посмотреть в таблице Список флейворов фиксированной конфигурации во всех пулах.

Посмотрите подробное описание ресурса openstack_compute_instance_v2.

5. Создать облачный балансировщик нагрузки⁠

1. Создать облачный балансировщик нагрузки⁠

resource "openstack_lb_loadbalancer_v2" "load_balancer_1" {
  name          = "load-balancer"
  vip_subnet_id = openstack_networking_subnet_v2.subnet_1.id
  flavor_id     = "ac18763b-1fc5-457d-9fa7-b0d339ffb336"
}

Здесь flavor_id — ID флейвора. Флейворы соответствуют типам балансировщика нагрузки и определяют количество vCPU, RAM и количество инстансов балансировщика. Например, ac18763b-1fc5-457d-9fa7-b0d339ffb336 — ID для создания балансировщика с типом Продвинутый с резервированием в пуле ru-9. Список флейворов можно посмотреть в таблице Список флейворов балансировщика нагрузки во всех пулах.

Посмотрите подробное описание ресурса openstack_lb_loadbalancer_v2.

2. Создать правило⁠

resource "openstack_lb_listener_v2" "listener_1" {
  name            = "listener"
  protocol        = "TCP"
  protocol_port   = "80"
  loadbalancer_id = openstack_lb_loadbalancer_v2.load_balancer_1.id
}

Здесь:

protocol — протокол для балансировщика, например TCP. Посмотрите доступные комбинации протоколов для балансировщика и сервера;
protocol_port — порт входящего трафика для балансировщика.

Посмотрите подробное описание ресурса openstack_lb_listener_v2.

3. Создать целевую группу⁠

resource "openstack_lb_pool_v2" "pool_1" {
  name        = "pool"
  protocol    = "PROXY"
  lb_method   = "ROUND_ROBIN"
  listener_id = openstack_lb_listener_v2.listener_1.id
}

Здесь:

protocol — протокол для серверов, например PROXY. Посмотрите доступные комбинации протоколов для балансировщика и сервера;
lb_method — алгоритм распределения запросов. Доступны алгоритмы ROUND_ROBIN и LEAST_CONNECTIONS.

Посмотрите подробное описание ресурса openstack_lb_pool_v2.

4. Добавить сервер в целевую группу⁠

resource "openstack_lb_member_v2" "member_1" {
  name          = "member"
  subnet_id     = openstack_networking_subnet_v2.subnet_1.id
  pool_id       = openstack_lb_pool_v2.pool_1.id
  address       = "192.168.199.4"
  protocol_port = "80"
}

Здесь:

address — приватный IP-адрес сервера, например 192.168.199.4;
protocol_port — порт для серверов в правиле.

Посмотрите подробное описание ресурса openstack_lb_member_v2.

5. Создать проверку доступности⁠

resource "openstack_lb_monitor_v2" "monitor_1" {
  name        = "monitor"
  pool_id     = openstack_lb_pool_v2.pool_1.id
  type        = "HTTP"
  delay       = "10"
  timeout     = "4"
  max_retries = "5"
}

Здесь:

type — тип проверки, например HTTP;
delay — интервал в секундах, с которым балансировщик отправляет проверяющие запросы серверам;
timeout — таймаут соединения (время ожидания ответа);
max_retries — количество успешных обращений подряд, после которых сервер переводится в рабочее состояние (порог успеха).

Посмотрите подробное описание ресурса openstack_lb_monitor_v2.

6. Создать публичный IP-адрес и подключить к балансировщику⁠

Публичный IP-адрес будет подключен к порту балансировщика нагрузки и ассоциирован с приватным IP.

resource "openstack_networking_floatingip_v2" "floatingip_1" {
  pool    = "external-network"
  port_id = openstack_lb_loadbalancer_v2.load_balancer_1.vip_port_id
}

Посмотрите подробное описание ресурса openstack_networking_floatingip_v2.

7. Получить IP-адрес балансировщика нагрузки⁠

output "public_ip_address" {
  value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
}

Пример создания инфраструктуры с облачным балансировщиком нагрузки

Конфигурационные файлы⁠​

1. Опционально: настроить провайдеры⁠​

2. Создать приватную сеть и подсеть⁠​

3. Создать облачный роутер, подключенный к внешней сети⁠​

4. Создать облачный сервер⁠​

1. Создать пару SSH-ключей⁠​

2. Создать порт для облачного сервера⁠​

3. Получить образ⁠​

4. Создать загрузочный сетевой диск⁠​

5. Создать облачный сервер⁠​

5. Создать облачный балансировщик нагрузки⁠​

1. Создать облачный балансировщик нагрузки⁠​

2. Создать правило⁠​

3. Создать целевую группу⁠​

4. Добавить сервер в целевую группу⁠​

5. Создать проверку доступности⁠​

6. Создать публичный IP-адрес и подключить к балансировщику⁠​

7. Получить IP-адрес балансировщика нагрузки⁠​

Конфигурационные файлы⁠

1. Опционально: настроить провайдеры⁠

2. Создать приватную сеть и подсеть⁠

3. Создать облачный роутер, подключенный к внешней сети⁠

4. Создать облачный сервер⁠

1. Создать пару SSH-ключей⁠

2. Создать порт для облачного сервера⁠

3. Получить образ⁠

4. Создать загрузочный сетевой диск⁠

5. Создать облачный сервер⁠

5. Создать облачный балансировщик нагрузки⁠

1. Создать облачный балансировщик нагрузки⁠

2. Создать правило⁠

3. Создать целевую группу⁠

4. Добавить сервер в целевую группу⁠

5. Создать проверку доступности⁠

6. Создать публичный IP-адрес и подключить к балансировщику⁠

7. Получить IP-адрес балансировщика нагрузки⁠