Создать образ и настроить к нему доступ в другом проекте

Последнее изменение: 31 июля 2025

Мы рекомендуем создавать ресурсы по порядку. Если вы создаете все ресурсы единовременно, Terraform будет учитывать зависимости между ресурсами, которые вы указали в конфигурационном файле. Если зависимости не указаны, ресурсы будут создаваться параллельно, что может приводить к ошибкам. Например, ресурс, который требуется для создания другого ресурса, может быть еще не создан.

1. Настройте провайдеры для исходного проекта.

2. Создайте образ.

3. Настройте доступ к образу в другом проекте.

4. Настройте провайдеры для целевого проекта.

5. Примите образ в целевом проекте.

Конфигурационные файлы

Пример файла для настройки провайдеров

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Пример файла для создания образа и настройки доступа к образу другим проектам

resource "openstack_images_image_v2" "image_1" {
    name             = "Debian 12.10"
    container_format = "bare"
    disk_format      = "qcow2"
    visibility       = "shared"

    properties = {
        key = "value"
    }
}

resource "openstack_images_image_access_v2" "member_1" {
    image_id  = openstack_images_image_v2.image_1.id
    member_id = "bed6b6cbb86a4e2d8dc2735c2f1000e4"
}

Пример файла для принятия образа в целевом проекте

data "openstack_images_image_v2" "image_1" {
    name          = "Debian 12.10"
    visibility    = "shared"
    member_status = "all"
}

resource "openstack_images_image_access_accept_v2" "member_1" {
    image_id = data.openstack_images_image_v2.image_1.id
    status   = "accepted"
}

1. Настроить провайдеры для исходного проекта

Если вы настроили провайдеры Selectel и OpenStack, пропустите этот шаг.

1. Убедитесь, что в панели управления вы создали сервисного пользователя с ролями member в области доступа Аккаунт и iam_admin.

2. Создайте директорию для хранения конфигурационных файлов и отдельный файл с расширением .tf для настройки провайдеров.

3. В файл для настройки провайдеров добавьте провайдеры Selectel и OpenStack:

   terraform {
     required_providers {
       selectel  = {
         source  = "selectel/selectel"
         version = "~> 6.0"
       }
       openstack = {
         source  = "terraform-provider-openstack/openstack"
         version = "2.1.0"
       }
     }
   }

   Здесь version — версии провайдеров. Актуальную версию можно посмотреть в документации Selectel (в Terraform Registry и GitHub) и OpenStack (в Terraform Registry и GitHub).

   Подробнее о продуктах, услугах и сервисах, которыми можно управлять с помощью провайдеров, в инструкции Провайдеры Selectel и OpenStack.

4. Инициализируйте провайдер Selectel:

   provider "selectel" {
     domain_name = "123456"
     username    = "user"
     password    = "password"
     auth_region = "ru-9"
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
   }

   Здесь:

   • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
   • username — имя сервисного пользователя с ролями member в области доступа Аккаунт и iam_admin. Можно посмотреть в панели управления: в верхнем меню нажмите Аккаунт → раздел Сервисные пользователи (раздел доступен только Владельцу аккаунта и пользователю с ролью iam_admin);
   • password — пароль сервисного пользователя. Можно посмотреть при создании пользователя или изменить на новый;
   • auth_region — пул для авторизации, например ru-9. Создавать ресурсы можно в других пулах. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

5. Создайте проект:

   resource "selectel_vpc_project_v2" "project_1" {
     name = "project"
   }

   Посмотрите подробное описание ресурса selectel_vpc_project_v2.

6. Создайте сервисного пользователя для доступа к проекту и назначьте ему роль member в области доступа Проект:

   resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
     name         = "username"
     password     = "password"
     role {
       role_name  = "member"
       scope      = "project"
       project_id = selectel_vpc_project_v2.project_1.id
     }
   }

   Здесь:

   • username — имя пользователя;
   • password — пароль пользователя. Пароль должен быть не короче восьми символов и содержать латинские буквы разных регистров и цифры;
   • project_id — ID проекта. Можно посмотреть в панели управления: в верхнем меню нажмите Продукты и выберите Облачные серверы → откройте меню проектов → в строке нужного проекта нажмите .

   Посмотрите подробное описание ресурса selectel_iam_serviceuser_v1.

7. Инициализируйте провайдер OpenStack:

   provider "openstack" {
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
     domain_name = "123456"
     tenant_id   = selectel_vpc_project_v2.project_1.id
     user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
     password    = selectel_iam_serviceuser_v1.serviceuser_1.password
     region      = "ru-9"
   }

   Здесь:

   • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
   • region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

8. Если одновременно с настройкой провайдеров вы создаете ресурсы, то для ресурсов OpenStack добавьте аргумент depends_on. Например, для ресурса openstack_networking_network_v2:

   resource "openstack_networking_network_v2" "network_1" {
     name           = "private-network"
     admin_state_up = "true"
   
     depends_on = [
       selectel_vpc_project_v2.project_1,
       selectel_iam_serviceuser_v1.serviceuser_1
     ]
   }

9. Опционально: если вы хотите использовать зеркало, создайте отдельный конфигурационный файл Terraform CLI и добавьте в него блок:

   provider_installation {
     network_mirror {
       url = "https://tf-proxy.selectel.ru/mirror/v1/"
       include = ["registry.terraform.io/*/*"]
     }
     direct {
       exclude = ["registry.terraform.io/*/*"]
     }
   }

   Подробнее о настройках зеркал в инструкции CLI Configuration File документации HashiCorp.

10. Откройте CLI.

11. Инициализируйте конфигурацию Terraform в директории:

    terraform init

12. Проверьте, что конфигурационные файлы составлены без ошибок:

    terraform validate

13. Отформатируйте конфигурационные файлы:

    terraform fmt

14. Проверьте, какие ресурсы будут созданы:

    terraform plan

15. Примените изменения и создайте ресурсы:

    terraform apply

16. Подтвердите создание — введите yes и нажмите Enter. Созданные ресурсы отобразятся в панели управления.

17. Если для создания ресурсов оказалось недостаточно квот, увеличьте квоты.

2. Создать образ

resource "openstack_images_image_v2" "image_1" {
    name             = "Debian 12.10"
    container_format = "bare"
    disk_format      = "qcow2"
    visibility       = "shared"

    properties = {
        key = "value"
    }
}

Здесь:

• container_format — формат контейнера. Доступные значения —ami, ari, aki, bare, ovf;
• disk_format — формат диска образа. Доступные значения — ami, ari, aki, vhd, vmdk, raw, qcow2, vdi, iso;
• visibility = "shared" — образ можно добавлять в другие проекты.

Посмотрите подробное описание ресурса openstack_images_image_v2.

3. Настроить доступ к образу в исходном проекте

resource "openstack_images_image_access_v2" "member_1" {
    image_id  = openstack_images_image_v2.image_1.id
    member_id = "bed6b6cbb86a4e2d8dc2735c2f1000e4"
}

Здесь member_id — ID целевого проекта. Можно посмотреть в панели управления: в верхнем меню нажмите Продукты → Облачные серверы → откройте меню проектов → в строке нужного проекта нажмите .

Посмотрите подробное описание ресурса openstack_images_image_access_v2.

4. Настроить провайдеры для целевого проекта

Создайте отдельный конфигурационный файл и настройте провайдеры под аккаунтом и проектом, для которого настроили доступ к образу.

1. Убедитесь, что в панели управления вы создали сервисного пользователя с ролями member в области доступа Аккаунт и iam_admin.

2. Создайте директорию для хранения конфигурационных файлов и отдельный файл с расширением .tf для настройки провайдеров.

3. В файл для настройки провайдеров добавьте провайдеры Selectel и OpenStack:

   terraform {
     required_providers {
       selectel  = {
         source  = "selectel/selectel"
         version = "~> 6.0"
       }
       openstack = {
         source  = "terraform-provider-openstack/openstack"
         version = "2.1.0"
       }
     }
   }

   Здесь version — версии провайдеров. Актуальную версию можно посмотреть в документации Selectel (в Terraform Registry и GitHub) и OpenStack (в Terraform Registry и GitHub).

   Подробнее о продуктах, услугах и сервисах, которыми можно управлять с помощью провайдеров, в инструкции Провайдеры Selectel и OpenStack.

4. Инициализируйте провайдер Selectel:

   provider "selectel" {
     domain_name = "123456"
     username    = "user"
     password    = "password"
     auth_region = "ru-9"
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
   }

   Здесь:

   • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
   • username — имя сервисного пользователя с ролями member в области доступа Аккаунт и iam_admin. Можно посмотреть в панели управления: в верхнем меню нажмите Аккаунт → раздел Сервисные пользователи (раздел доступен только Владельцу аккаунта и пользователю с ролью iam_admin);
   • password — пароль сервисного пользователя. Можно посмотреть при создании пользователя или изменить на новый;
   • auth_region — пул для авторизации, например ru-9. Создавать ресурсы можно в других пулах. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

5. Создайте проект:

   resource "selectel_vpc_project_v2" "project_1" {
     name = "project"
   }

   Посмотрите подробное описание ресурса selectel_vpc_project_v2.

6. Создайте сервисного пользователя для доступа к проекту и назначьте ему роль member в области доступа Проект:

   resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
     name         = "username"
     password     = "password"
     role {
       role_name  = "member"
       scope      = "project"
       project_id = selectel_vpc_project_v2.project_1.id
     }
   }

   Здесь:

   • username — имя пользователя;
   • password — пароль пользователя. Пароль должен быть не короче восьми символов и содержать латинские буквы разных регистров и цифры;
   • project_id — ID проекта. Можно посмотреть в панели управления: в верхнем меню нажмите Продукты и выберите Облачные серверы → откройте меню проектов → в строке нужного проекта нажмите .

   Посмотрите подробное описание ресурса selectel_iam_serviceuser_v1.

7. Инициализируйте провайдер OpenStack:

   provider "openstack" {
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
     domain_name = "123456"
     tenant_id   = selectel_vpc_project_v2.project_1.id
     user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
     password    = selectel_iam_serviceuser_v1.serviceuser_1.password
     region      = "ru-9"
   }

   Здесь:

   • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
   • region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

8. Если одновременно с настройкой провайдеров вы создаете ресурсы, то для ресурсов OpenStack добавьте аргумент depends_on. Например, для ресурса openstack_networking_network_v2:

   resource "openstack_networking_network_v2" "network_1" {
     name           = "private-network"
     admin_state_up = "true"
   
     depends_on = [
       selectel_vpc_project_v2.project_1,
       selectel_iam_serviceuser_v1.serviceuser_1
     ]
   }

9. Опционально: если вы хотите использовать зеркало, создайте отдельный конфигурационный файл Terraform CLI и добавьте в него блок:

   provider_installation {
     network_mirror {
       url = "https://tf-proxy.selectel.ru/mirror/v1/"
       include = ["registry.terraform.io/*/*"]
     }
     direct {
       exclude = ["registry.terraform.io/*/*"]
     }
   }

   Подробнее о настройках зеркал в инструкции CLI Configuration File документации HashiCorp.

10. Откройте CLI.

11. Инициализируйте конфигурацию Terraform в директории:

    terraform init

12. Проверьте, что конфигурационные файлы составлены без ошибок:

    terraform validate

13. Отформатируйте конфигурационные файлы:

    terraform fmt

14. Проверьте, какие ресурсы будут созданы:

    terraform plan

15. Примените изменения и создайте ресурсы:

    terraform apply

16. Подтвердите создание — введите yes и нажмите Enter. Созданные ресурсы отобразятся в панели управления.

17. Если для создания ресурсов оказалось недостаточно квот, увеличьте квоты.

5. Принять образ в целевом проекте

data "openstack_images_image_v2" "image_1" {
    name          = "Debian 12.10"
    visibility    = "shared"
    member_status = "all"
}

resource "openstack_images_image_access_accept_v2" "member_1" {
    image_id = data.openstack_images_image_v2.image_1.id
    status   = "accepted"
}

Здесь status = "accepted" — образ будет принят в целевом проекте.

Посмотрите подробное описание ресурса openstack_images_image_access_accept_v2.