Create a MySQL semi-sync cluster

We recommend that you create resources in order. If you create all resources at once, Terraform will take into account the dependencies between resources that you specify in the configuration file. If dependencies are not specified, resources will be created in parallel, which can cause errors. For example, a resource that is required to create another resource may not have been created yet.

Configuration files⁠

Example file for configuring providers

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Example file for creating a MySQL semi-sync cluster of fixed configuration

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  filter {
    engine  = "mysql_native"
    version = "8"
  }
}

data "selectel_dbaas_flavor_v1" "flavor_1" {
project_id = selectel_vpc_project_v2.project_1.id
region     = "ru-9"
filter {
  datastore_type_id = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
  fl_size           = "standard"
  vcpus             = 4
  ram               = 16384
  disk              = 128
  }
}

resource "selectel_dbaas_mysql_datastore_v1" "datastore_1" {
  name       = "datastore-1"
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
  subnet_id  = openstack_networking_subnet_v2.subnet_1.id
  node_count = 3
  flavor_id  = data.selectel_dbaas_flavor_v1.flavor_1.flavors[0].id
}

resource "selectel_dbaas_user_v1" "user_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
  name         = "user"
  password     = "secret"
}

resource "selectel_dbaas_mysql_database_v1" "database_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
  name         = "database_1"
}

resource "selectel_dbaas_grant_v1" "grant_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
  database_id  = selectel_dbaas_mysql_database_v1.database_1.id
  user_id      = selectel_dbaas_user_v1.user_1.id
}

Example file for creating a MySQL semi-sync cluster of arbitrary configuration

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  filter {
    engine  = "mysql_native"
    version = "8"
  }
}

resource "selectel_dbaas_mysql_datastore_v1" "datastore_1" {
  name       = "datastore-1"
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
  subnet_id  = openstack_networking_subnet_v2.subnet_1.id
  node_count = 3
  flavor {
    vcpus = 1
    ram   = 4096
    disk  = 32
  }
}

resource "selectel_dbaas_user_v1" "user_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
  name         = "user"
  password     = "secret"
}

resource "selectel_dbaas_mysql_database_v1" "database_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
  name         = "database_1"
}

resource "selectel_dbaas_grant_v1" "grant_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
  database_id  = selectel_dbaas_mysql_database_v1.database_1.id
  user_id      = selectel_dbaas_user_v1.user_1.id
}

1. Optional: configure providers⁠

If you have configured Selectel and OpenStack providers, skip this step.

Ensure that in the Control Panel you have created a service user with the Account Administrator and User Administrator roles.
Create a directory to store the configuration files and a separate file with a .tf extension to configure the providers.
Add Selectel and OpenStack providers to the file to configure the providers:
```
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Here version — versions of providers. The current version can be found in Selectel (in Terraform Registry and GitHub) and OpenStack (in Terraform Registry and GitHub) documentation.

Learn more about the products, services, and services that can be managed with providers in the Selectel and OpenStack Providers instruction.
Initialize the Selectel provider:
```
provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}
```
Here:
- domain_name — Selectel account number. You can look it up in control panel in the upper right corner;
- username — username service user with the roles Account Administrator and User Administrator. Can be viewed in the control panel section Access Control → User Management → tab Service Users (the section is available only to the Account Owner and User Administrator);
- password — password of the service user. You can view it when creating a user or change it to a new one;
- auth_region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.
Create a project:
```
resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}
```
View a detailed description of the selectel_vpc_project_v2 resource.
Create a service user to access the project and assign the Project Administrator role to it:
```
resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}
```
Here:
- username — username;
- password — user password. The password must be no shorter than eight characters and contain Latin letters of different cases and digits;
- project_id — Project ID. You can view it in control panel: section Cloud Platform → open the projects menu (the name of the current project) → in the line of the required project press .
View a detailed description of the selectel_iam_serviceuser_v1 resource.

Initialize the OpenStack provider:

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Here:

domain_name — Selectel account number. You can look it up in control panel in the upper right corner;
region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

If you create resources at the same time as configuring providers, add the depends_on argument for OpenStack resources . For example, for the resource openstack_networking_network_v2:

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    selectel_vpc_project_v2.project_1,
    selectel_iam_serviceuser_v1.serviceuser_1
  ]
}

Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add a block to it:
```
provider_installation {
  network_mirror {
    url = "https://tf-proxy.selectel.ru/mirror/v1/"
    include = ["registry.terraform.io/*/*"]
  }
  direct {
    exclude = ["registry.terraform.io/*/*"]
  }
}
```
See the CLI Configuration File instructions in HashiCorp's CLI Configuration File documentation for more information on configuring mirrors.
Open the CLI.
Initialize the Terraform configuration in the directory:
```
terraform init
```
Check that the configuration files have been compiled without errors:
```
terraform validate
```
Format the configuration files:
```
terraform fmt
```
Check the resources that will be created:
```
terraform plan
```
Apply the changes and create the resources:
```
terraform apply
```
Confirm the creation — type yes and press Enter. The created resources are displayed in the control panel.
If there were not enough quotas to create resources, increase the quotas.

2. Create a private network and subnet⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here cidr is the CIDR of the private subnet, for example 192.168.199.0/24.

See a detailed description of the resources:

3. Create a cluster⁠

Fixed configuration
Arbitrary configuration

data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  filter {
    engine  = "mysql_native"
    version = "8"
  }
}

data "selectel_dbaas_flavor_v1" "flavor_1" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  filter {
    datastore_type_id = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
    fl_size           = "standard"
    vcpus             = 4
    ram               = 16384
    disk              = 128
    }
  }


resource "selectel_dbaas_mysql_datastore_v1" "datastore_1" {
  name       = "datastore-1"
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
  subnet_id  = openstack_networking_subnet_v2.subnet_1.id
  node_count = 3
  flavor_id  = data.selectel_dbaas_flavor_v1.flavor_1.flavors[0].id
}

Here:

region — pool, e.g. ru-9. The list of available pools can be found in the instructions Availability matrices;
filter — cloud database type filter:
- engine — cloud database type. For a MySQL semi-sync cluster, specify mysql_native;
- version — version of the cloud database. For a list of available versions, see the instructions Versions and configurations;
nodes_count — number of nodes. The maximum number of nodes is 3;
filter — filter of fixed cluster configurations. For a list of available configurations, see the instructions Versions and configurations;
- fl_size — line of fixed configurations. The available values are standard (for Standard, CPU and Memory lines) and high_freq (for the HighFreq line);
- vcpus — number of vCPUs;
- ram — the amount of RAM in MB;
- disk — disk size in GB.

View a detailed description of the data sources and resources:

data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  filter {
    engine  = "mysql_native"
    version = "8"
  }
}

resource "selectel_dbaas_mysql_datastore_v1" "datastore_1" {
  name       = "datastore-1"
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
  subnet_id  = openstack_networking_subnet_v2.subnet_1.id
  node_count = 3
  flavor {
    vcpus = 1
    ram   = 4096
    disk  = 32
  }
}

Here:

region — pool, e.g. ru-9. The list of available pools can be found in the instructions Availability matrices;
filter — cloud database type filter:
- engine — cloud database type. For a MySQL semi-sync cluster, specify mysql_native;
- version — version of the cloud database. For a list of available versions, see the instructions Versions and configurations;
nodes_count — number of nodes. The maximum number of nodes is 6;
flavor — arbitrary cluster configuration. The available values of the arbitrary configurations can be seen in the instructions Versions and configurations:
- vcpus — number of vCPUs;
- ram — the amount of RAM in MB;
- disk — disk size in GB.

View a detailed description of the data sources and resources:

4. Create a user⁠

resource "selectel_dbaas_user_v1" "user_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
  name         = "user"
  password     = "secret"
}

Here:

region — pool in which the cluster is located;
name — user name;
password — user password.

View the detailed resource description of selectel_dbaas_user_v1.

5. Create a database⁠

resource "selectel_dbaas_mysql_database_v1" "database_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
  name         = "database_1"
}

Here region is the pool in which the cluster resides.

View the detailed resource description of selectel_dbaas_mysql_database_v1.

6. Grant the user access to the database⁠

resource "selectel_dbaas_grant_v1" "grant_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
  database_id  = selectel_dbaas_mysql_database_v1.database_1.id
  user_id      = selectel_dbaas_user_v1.user_1.id
}

View the detailed resource description of selectel_dbaas_grant_v1.

Create a MySQL semi-sync cluster

Configuration files⁠​

1. Optional: configure providers⁠​

2. Create a private network and subnet⁠​

3. Create a cluster⁠​

4. Create a user⁠​

5. Create a database⁠​

6. Grant the user access to the database⁠​

Configuration files⁠

1. Optional: configure providers⁠

2. Create a private network and subnet⁠

3. Create a cluster⁠

4. Create a user⁠

5. Create a database⁠

6. Grant the user access to the database⁠