Create a cloud server of arbitrary configuration with a bootable network disk and an additional network disk

Last update: December 17 2024

Create a cloud server of arbitrary configuration with a bootable network disk and an additional network disk

We recommend create resources in order. If you create all the resources that are described in the configuration file The Terraform creates resources regardless of the order in which they are listed in the file.

1. Optional: configure your ISPs.
2. Create an SSH key pair.
3. Create a flavor with a network drive.
4. Create a private network and subnet.
5. Create a cloud router connected to an external network.
6. Create a port for the cloud server.
7. Get an image.
8. Create a bootable network disk.
9. Create an additional network drive.
10. Create a cloud server.
11. Create a public IP address.
12. Assign the association of the public and private IP address of the cloud server.
13. Get the IP address of the cloud server.

Configuration files⁠

Example file for configuring providers

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "6.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Example file for creating a server

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

resource "openstack_compute_flavor_v2" "flavor_1" {
  name      = "custom-flavor-with-network-volume"
  vcpus     = 2
  ram       = 2048
  disk      = 0
  is_public = false

  lifecycle {
    create_before_destroy = true
  }

}

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = openstack_networking_network_v2.network_1.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }
}

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.ru-9a"
  availability_zone    = "ru-9a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

resource "openstack_blockstorage_volume_v3" "volume_2" {
  name                 = "additional-volume-for-server"
  size                 = "7"
  volume_type          = "universal.ru-9a"
  availability_zone    = "ru-9a"
  enable_online_resize = true
}

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = openstack_compute_flavor_v2.flavor_1.id
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_2.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = -1
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

resource "openstack_networking_floatingip_v2" "floatingip_1" {
  pool = "external-network"
}

resource "openstack_networking_floatingip_associate_v2" "association_1" {
  port_id     = openstack_networking_port_v2.port_1.id
  floating_ip = openstack_networking_floatingip_v2.floatingip_1.address
}

output "public_ip_address" {
  value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
}

optional: configure providers⁠

If you have configured Selectel and OpenStack providers, skip this step.

1. Make sure that in the control panel you created a service user with the Account Administrator and User Administrator roles.

2. Create a directory to store the configuration files and a separate file with the extension .tf to configure the ISPs.

3. Add Selectel and OpenStack providers to the file to configure the providers:

   terraform {
     required_providers {
       selectel  = {
         source  = "selectel/selectel"
         version = "6.0.0"
       }
       openstack = {
         source  = "terraform-provider-openstack/openstack"
         version = "2.1.0"
       }
     }
   }

   Here version — provider versions. The current version can be found in the Selectel documentation (in the Terraform Registry и GitHub) and OpenStack (in Terraform Registry и GitHub).

   Read more about products, services and services that can be managed with providers in the instructions Selectel and OpenStack providers.

4. Initialize the Selectel provider:

   provider "selectel" {
     domain_name = "123456"
     username    = "user"
     password    = "password"
   }

   Here:

   • domain_name — Selectel account number. You can look in control panels in the upper right-hand corner;
   • username — name service user with the Account Administrator and User Administrator roles. You can look in control panels: section Access control → User management → tab Service users (the section is only available to the Account Owner and User Administrator);
   • password — service user password. You can view it when creating a user or change to a new one.

5. Create a project:

   resource "selectel_vpc_project_v2" "project_1" {
     name = "project"
   }

   Check out the detailed description of the resource selectel_vpc_project_v2.

6. Create a service user to access the project and assign the Project Administrator role to it:

   resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
     name         = "username"
     password     = "password"
     role {
       role_name  = "member"
       scope      = "project"
       project_id = selectel_vpc_project_v2.project_1.id 
     }
   }

   Here:

   • username — username;
   • password — user password. The password must be no shorter than eight characters and contain Latin letters of different cases and digits;
   • project_id — Project ID. You can look in control panels: section Cloud platform → open the project menu (name of the current project) → in the line of the desired project, click .

   Check out the detailed description of the resource selectel_iam_serviceuser_v1.

7. Initialize the OpenStack provider:

   provider "openstack" {
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
     domain_name = "123456"
     tenant_id   = selectel_vpc_project_v2.project_1.id
     user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
     password    = selectel_iam_serviceuser_v1.serviceuser_1.password
     region      = "ru-9"
   }

   Here:

   • domain_name — Selectel account number. You can look in control panels in the upper right-hand corner;
   • region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

8. If at the same time you are setting up your providers resource creation then for OpenStack resources add the argument depends_on. For example, for the openstack_networking_network_v2 resource:

   resource "openstack_networking_network_v2" "network_1" {
     name           = "private-network"
     admin_state_up = "true"
   
     depends_on = [
       selectel_vpc_project_v2.project_1,
       selectel_iam_serviceuser_v1.serviceuser_1
     ]
   }

9. Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add a block to it:

   provider_installation {
     network_mirror {
       url = "https://tf-proxy.selectel.ru/mirror/v1/"
       include = ["registry.terraform.io/*/*"]
     }
     direct {
       exclude = ["registry.terraform.io/*/*"]
     }
   }

   Read more about mirror settings in the manual CLI Configuration File HashiCorp documentation.

10. Open the CLI.

11. Initialize the Terraform configuration in the directory:

    terraform init

12. Check that the configuration files have been compiled without errors:

    terraform validate

13. Format the configuration files:

    terraform fmt

14. Check the resources that will be created:

    terraform plan

15. Apply the changes and create the resources:

    terraform apply

16. Confirm creation — enter yes and press Enter. The created resources are displayed in the control panel.

17. If there were insufficient quotas to create resources, increase quotas.

Create an SSH key pair⁠

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

Here. public_key — path to the public SSH key. If SSH keys have not been created, generate them.

Check out the detailed description of the resource selectel_vpc_keypair_v2.

Create a flavor with a network drive⁠

resource "openstack_compute_flavor_v2" "flavor_1" {
  name      = "custom-flavor-with-network-volume"
  vcpus     = 2
  ram       = 2048
  disk      = 0
  is_public = false

  lifecycle {
    create_before_destroy = true
  }

}

Here:

• vcpus — number of vCPUs;
• ram — RAM size in MB;
• disk — local disk size in GB. To create a flavor with a network disk, the value must be zero.

Take into account what's available values of arbitrary configurations.

Check out the detailed description of the resource openstack_compute_flavor_v2.

Create a private network and subnet⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here. cidr — CIDR of a private subnet, e.g. 192.168.199.0/24.

See a detailed description of the resources:

• openstack_networking_network_v2;
• openstack_networking_subnet_v2.

Create a cloud router connected to an external network⁠

A cloud router connected to an external network acts as a 1:1 NAT for access from a private network to the Internet through the public IP address of the router.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

See a detailed description of the resources:

• openstack_networking_network_v2;
• openstack_networking_router_v2;
• openstack_networking_router_interface_v2.

Create a port for the cloud server⁠

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = openstack_networking_network_v2.network_1.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }
}

Check out the detailed description of the resource openstack_networking_port_v2.

Get an image⁠

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

Check out the detailed description of the data source openstack_images_image_v2.

Create a bootable network disk⁠

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.ru-9a"
  availability_zone    = "ru-9a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

Here:

• size — disk size in GB. Consider network disk limits to the maximum size;
• volume_type — ID or name network drive type. For example, fast.ru-9a — name to create a network drive with the SSD type Fast in the pool segment ru-9a. The list of types can be seen in the table List of network disk types in all pool segments;
• availability_zone — pool segment where the network drive will be created, e.g. ru-9a. The list of available pool segments can be found in the instructions Availability matrix.

Check out the detailed description of the resource openstack_blockstorage_volume_v3.

Create an additional network drive⁠

resource "openstack_blockstorage_volume_v3" "volume_2" {
  name                 = "additional-volume-for-server"
  size                 = "7"
  volume_type          = "universal.ru-9a"
  availability_zone    = "ru-9a"
  enable_online_resize = true
}

Here:

• size — disk size in GB. Consider network disk limits to the maximum size;
• volume_type — ID or name network drive type. For example, universal.ru-9a — name to create a network drive with the SSD Universal type in the pool segment ru-9a. The list of types can be seen in the table List of network disk types in all pool segments;
• availability_zone — pool segment where the network drive will be created, e.g. ru-9a. The list of available pool segments can be found in the instructions Availability matrix.

Check out the detailed description of the resource openstack_blockstorage_volume_v3.

Create a cloud server⁠

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = openstack_compute_flavor_v2.flavor_1.id
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_2.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = -1
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Here. availability_zone — pool segment where the cloud server will be created, e.g. ru-9a. The list of available pool segments can be found in the instructions Availability matrix.

Check out the detailed description of the resource openstack_compute_instance_v2.

Create a public IP address⁠

resource "openstack_networking_floatingip_v2" "floatingip_1" {
  pool = "external-network"
}

Check out the detailed description of the resource openstack_networking_floatingip_v2.

assign an association between the public and private IP address of the cloud server⁠

The public IP address will be connected to the cloud server port and associated with the private IP.

resource "openstack_networking_floatingip_associate_v2" "association_1" {
  port_id     = openstack_networking_port_v2.port_1.id
  floating_ip = openstack_networking_floatingip_v2.floatingip_1.address
}

Check out the detailed description of the resource openstack_networking_floatingip_associate_v2.

Get the IP address of the cloud server⁠

output "public_ip_address" {
  value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
}