Create several identical cloud servers in one private network via Terraform

We recommend creating resources in order. If you create all resources at once, Terraform will account for dependencies between resources that you specified in the configuration file. If dependencies are not specified, resources will be created in parallel, which may lead to errors. For instance, a resource required for creating another resource might not have been created yet.

Optional: configure providers.
Add a public SSH key.
Create a private network and subnet.
Create a cloud router connected to the internet.
Create ports for cloud servers.
Get an image.
Create cloud servers.
Create public IP addresses.
Associate public and private IP addresses of cloud servers.

Configuration files

Example file for configuring providers

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Example file for creating servers

    resource "selectel_vpc_keypair_v2" "keypair_1" {
        name       = "keypair"
        public_key = file("~/.ssh/id_rsa.pub")
        user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
    }

    resource "openstack_networking_network_v2" "network_1" {
        name           = "private-network"
        admin_state_up = "true"
    }

    resource "openstack_networking_subnet_v2" "subnet_1" {
        network_id = openstack_networking_network_v2.network_1.id
        cidr       = "192.168.199.0/24"
    }

    data "openstack_networking_network_v2" "external_network_1" {
        external = true
    }

    resource "openstack_networking_router_v2" "router_1" {
        name                = "router"
        external_network_id = data.openstack_networking_network_v2.external_network_1.id
    }

    resource "openstack_networking_router_interface_v2" "router_interface_1" {
        router_id = openstack_networking_router_v2.router_1.id
        subnet_id = openstack_networking_subnet_v2.subnet_1.id
    }

    resource "openstack_networking_port_v2" "port" {
        name       = "port"
        count      = 3
        network_id = openstack_networking_network_v2.network2.id

        fixed_ip {
            subnet_id = openstack_networking_subnet_v2.subnet_2.id
        }

    }

    data "openstack_images_image_v2" "image_1" {
        name        = "Ubuntu 20.04 LTS 64-bit"
        most_recent = true
        visibility  = "public"
    }

    resource "openstack_compute_instance_v2" "server" {
        name              = "server"
        count             = 3
        image_id          = data.openstack_images_image_v2.ubuntu.id
        flavor_id         = "1312"
        key_pair          = selectel_vpc_keypair_v2.keypair_1.name
        availability_zone = "ru-9a"

        network {
            port = openstack_networking_port_v2.port[count.index].id
        }

        lifecycle {
            ignore_changes = [image_id]
        }

        vendor_options {
            ignore_resize_confirmation = true
        }

    }

    resource "openstack_networking_floatingip_v2" "floatingip" {
        pool  = "external-network"
        count = 3
    }

    resource "openstack_networking_floatingip_associate_v2" "association" {
        count       = 3
        port_id     = openstack_networking_port_v2.port[count.index].id
        floating_ip = openstack_networking_floatingip_v2.floatingip[count.index].address
    }

1. Optional: configure providers

If you have already configured Selectel and OpenStack providers, skip this step.

Make sure you have created a service user in the control panel member with roles in the Account access scope and iam.admin.
Create a directory to store configuration files and a separate file with the .tf extension to configure providers.
Add the Selectel and OpenStack providers to the file for provider configuration:
```
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 7.1.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Here version is the provider version. The current version can be found in the Selectel documentation (in Terraform Registry and GitHub) and OpenStack (in Terraform Registry and GitHub).

For more information about products, services, and features that can be managed using providers, see the Selectel and OpenStack Providers guide.
Initialize the Selectel provider:
```
provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}
```
Where:
- domain_name — Selectel account number. You can find it in the control panel in the top-right corner;
- username — the name of the service user with the member role in the Account access scope and iam.admin. You can view it in the control panel: in the top menu, click IAM → Service Users section (this section is only available to the account owner and users with the iam.admin role);
- password — service user password. You can view it when creating the user or change it to a new one;
- auth_region — pool for authentication in the ru-9 format; do not use pools in the SPB-2 format. The authentication pool may not match the pool where you create resources. The list of available pools can be found in the Availability Matrix instructions.
Create a project:
```
resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}
```
See the detailed resource description for selectel_vpc_project_v2.
Create a service user for project access and assign the member role in the Project access scope:
```
resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id
  }
}
```
Where:
- username — user name;
- password — user password. The password must be at least 20 characters long and include at least:
  - one uppercase and one lowercase Latin letter (A-Z, a-z);
  - one digit (0-9);
  - one special character from the ASCII Printable 7-Bit Special Characters list:
    !"#$%&'()*+,-./:;<=>?@[]^_{|}~;
- project_id — project ID. You can find it in the control panel: in the top menu, click IAM → Projects section → in the row of the required project, click .
See the detailed resource description for selectel_iam_serviceuser_v1.

Initialize the OpenStack provider:

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Where:

domain_name — Selectel account number. You can view it in the control panel in the top-right corner;
region — pool, for example, ru-9. All resources will be created in this pool. The list of available pools can be found in the Availability Matrix instructions.

If you are creating resources at the same time as configuring providers, add the depends_on argument for OpenStack resources. For example, for the openstack_networking_network_v2 resource:

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    selectel_vpc_project_v2.project_1,
    selectel_iam_serviceuser_v1.serviceuser_1
  ]
}

Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add the following block to it:
```
provider_installation {
  network_mirror {
    url = "https://tf-proxy.selectel.ru/mirror/v1/"
    include = ["registry.terraform.io/*/*"]
  }
  direct {
    exclude = ["registry.terraform.io/*/*"]
  }
}
```
For more information on mirror settings, see the CLI Configuration File instructions in the HashiCorp documentation.
Open the CLI.
Initialize the Terraform configuration in the directory:
```
terraform init
```
Verify that the configuration files are syntactically correct:
```
terraform validate
```
Format the configuration files:
```
terraform fmt
```
Check which resources will be created:
```
terraform plan
```
Apply the changes and create the resources:
```
terraform apply
```
Confirm creation — enter yes and press Enter. The created resources will appear in the control panel.
If you do not have enough quotas to create resources, increase the quotas.

2. Add a public SSH key

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

Here public_key is the path to the public SSH key. If SSH keys are not generated, create them.

See the detailed description of the selectel_vpc_keypair_v2 resource.

3. Create a private network and subnet

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here cidr is the private subnet CIDR, for example 192.168.199.0/24.

See the detailed resource description:

4. Create a cloud router connected to the internet

A cloud router connected to the internet performs 1:1 NAT for traffic from a private network to the internet via the router's public IP address.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

See the detailed resource description:

5. Create ports for cloud servers

resource "openstack_networking_port_v2" "port" {
  name       = "port"
  count      = 3
  network_id = openstack_networking_network_v2.network2.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_2.id
  }
}

Here count is the number of ports.

See the detailed description of the openstack_networking_port_v2 resource.

6. Get an image

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

See the detailed description of the openstack_images_image_v2 data source.

7. Create cloud servers

resource "openstack_compute_instance_v2" "server" {
  name              = "server"
  count             = 3
  image_id          = data.openstack_images_image_v2.ubuntu.id
  flavor_id         = "1312"
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port[count.index].id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Where:

count is the number of servers;
flavor_id — flavor ID. For example, 1312 — ID of the fixed-configuration flavor from the Standard line with 1 vCPU, 2048 GB RAM, 16 GB local disk. The list of flavors can be viewed using the openstack flavor list command or in the List of fixed-configuration flavors in all pools;
availability_zone — pool segment in which cloud servers will be created, for example ru-9a. The list of available pool segments can be viewed in the Availability Matrix.

See the detailed description of the openstack_compute_instance_v2 resource.

8. Create public IP addresses

resource "openstack_networking_floatingip_v2" "floatingip" {
  count = 3
  pool  = "external-network"
}

Here count is the number of public IP addresses.

See the detailed description of the openstack_networking_floatingip_v2 resource.

9. Associate public and private IP addresses of cloud servers

Public IP addresses will be attached to cloud server ports and associated with private IP addresses.

resource "openstack_networking_floatingip_associate_v2" "association" {
  count       = 3
  port_id     = openstack_networking_port_v2.port[count.index].id
  floating_ip = openstack_networking_floatingip_v2.floatingip[count.index].address
}

Here count is the number of public and private IP address associations.

See the detailed description of the openstack_networking_floatingip_associate_v2 resource.