Create an SSH key pair and add a public SSH key

Last update: May 27 2025

Create an SSH key pair and add a public SSH key

We recommend that you create resources in order. If you create all resources at once, Terraform will take into account the dependencies between resources that you specify in the configuration file. If dependencies are not specified, resources will be created in parallel, which can cause errors. For example, a resource that is required to create another resource may not have been created yet.

1. Optional: configure the providers.

2. Create an SSH key pair.

3. Add a public SSH key.

Configuration files⁠

Example file for configuring providers

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Sample file for adding a public SSH key for all regions

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

Example file for adding a public SSH key for a specific region

resource "selectel_vpc_keypair_v2" "keypair_2" {
  name       = "keypair-ru-9"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_vpc_user_v2.user_1.id
  regions    = [
      "ru-9"
      ]
}

1. Optional: configure providers⁠

If you have configured Selectel and OpenStack providers, skip this step.

1. Ensure that in the Control Panel you have created a service user with the Account Administrator and User Administrator roles.

2. Create a directory to store the configuration files and a separate file with a .tf extension to configure the providers.

3. Add Selectel and OpenStack providers to the file to configure the providers:

   terraform {
     required_providers {
       selectel  = {
         source  = "selectel/selectel"
         version = "~> 6.0"
       }
       openstack = {
         source  = "terraform-provider-openstack/openstack"
         version = "2.1.0"
       }
     }
   }

   Here version — versions of providers. The current version can be found in Selectel (in Terraform Registry and GitHub) and OpenStack (in Terraform Registry and GitHub) documentation.

   Learn more about the products, services, and services that can be managed with providers in the Selectel and OpenStack Providers instruction.

4. Initialize the Selectel provider:

   provider "selectel" {
     domain_name = "123456"
     username    = "user"
     password    = "password"
     auth_region = "ru-9"
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
   }

   Here:

   • domain_name — Selectel account number. You can look it up in control panel in the upper right corner;
   • username — username service user with the roles Account Administrator and User Administrator. Can be viewed in the control panel section Access Control → User Management → tab Service Users (the section is available only to the Account Owner and User Administrator);
   • password — password of the service user. You can view it when creating a user or change it to a new one;
   • auth_region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

5. Create a project:

   resource "selectel_vpc_project_v2" "project_1" {
     name = "project"
   }

   View a detailed description of the selectel_vpc_project_v2 resource.

6. Create a service user to access the project and assign the Project Administrator role to it:

   resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
     name         = "username"
     password     = "password"
     role {
       role_name  = "member"
       scope      = "project"
       project_id = selectel_vpc_project_v2.project_1.id 
     }
   }

   Here:

   • username — username;
   • password — user password. The password must be no shorter than eight characters and contain Latin letters of different cases and digits;
   • project_id — Project ID. You can view it in control panel: section Cloud Platform → open the projects menu (the name of the current project) → in the line of the required project press .

   View a detailed description of the selectel_iam_serviceuser_v1 resource.

7. Initialize the OpenStack provider:

   provider "openstack" {
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
     domain_name = "123456"
     tenant_id   = selectel_vpc_project_v2.project_1.id
     user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
     password    = selectel_iam_serviceuser_v1.serviceuser_1.password
     region      = "ru-9"
   }

   Here:

   • domain_name — Selectel account number. You can look it up in control panel in the upper right corner;
   • region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

8. If you create resources at the same time as configuring providers, add the depends_on argument for OpenStack resources . For example, for the resource openstack_networking_network_v2:

   resource "openstack_networking_network_v2" "network_1" {
     name           = "private-network"
     admin_state_up = "true"
   
     depends_on = [
       selectel_vpc_project_v2.project_1,
       selectel_iam_serviceuser_v1.serviceuser_1
     ]
   }

9. Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add a block to it:

   provider_installation {
     network_mirror {
       url = "https://tf-proxy.selectel.ru/mirror/v1/"
       include = ["registry.terraform.io/*/*"]
     }
     direct {
       exclude = ["registry.terraform.io/*/*"]
     }
   }

   See the CLI Configuration File instructions in HashiCorp's CLI Configuration File documentation for more information on configuring mirrors.

10. Open the CLI.

11. Initialize the Terraform configuration in the directory:

    terraform init

12. Check that the configuration files have been compiled without errors:

    terraform validate

13. Format the configuration files:

    terraform fmt

14. Check the resources that will be created:

    terraform plan

15. Apply the changes and create the resources:

    terraform apply

16. Confirm the creation — type yes and press Enter. The created resources are displayed in the control panel.

17. If there were not enough quotas to create resources, increase the quotas.

2. Create an SSH key pair⁠

Create an SSH key pair on the local computer.

3. Add a public SSH key⁠

For all regions

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

Here public_key is the path to the public SSH key you created.

View a detailed description of the selectel_vpc_keypair_v2 resource.

For a specific region

resource "selectel_vpc_keypair_v2" "keypair_2" {
  name       = "keypair-ru-9"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_vpc_user_v2.user_1.id
  regions    = [
      "ru-9"
      ]
}

Here public_key is the path to the public SSH key you created.

View a detailed description of the selectel_vpc_keypair_v2 resource.