Skip to main content
Create multiple identical cloud servers on the same private network
Last update:

Create multiple identical cloud servers on the same private network

We recommend create resources in order. If you create all the resources that are described in the configuration file The Terraform creates resources regardless of the order in which they are listed in the file.


  1. Optional: configure your ISPs.

  2. Add a public SSH key.

  3. Create a private network and subnet.

  4. Create a cloud router connected to an external network.

  5. Create ports for cloud servers.

  6. Get an image.

  7. Create cloud servers.

  8. Create public IP addresses.

  9. Associate public and private cloud server IP addresses.

Configuration files⁠

Example file for configuring providers
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}
Sample file for creating servers
    resource "selectel_vpc_keypair_v2" "keypair_1" {
        name       = "keypair"
        public_key = file("~/.ssh/id_rsa.pub")
        user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
    }

    resource "openstack_networking_network_v2" "network_1" {
        name           = "private-network"
        admin_state_up = "true"
    }

    resource "openstack_networking_subnet_v2" "subnet_1" {
        network_id = openstack_networking_network_v2.network_1.id
        cidr       = "192.168.199.0/24"
    }

    data "openstack_networking_network_v2" "external_network_1" {
        external = true
    }

    resource "openstack_networking_router_v2" "router_1" {
        name                = "router"
        external_network_id = data.openstack_networking_network_v2.external_network_1.id
    }

    resource "openstack_networking_router_interface_v2" "router_interface_1" {
        router_id = openstack_networking_router_v2.router_1.id
        subnet_id = openstack_networking_subnet_v2.subnet_1.id
    }

    resource "openstack_networking_port_v2" "port" {
        name       = "port"
        count      = 3
        network_id = openstack_networking_network_v2.network2.id

        fixed_ip {
            subnet_id = openstack_networking_subnet_v2.subnet_2.id
        }

    }

    data "openstack_images_image_v2" "image_1" {
        name        = "Ubuntu 20.04 LTS 64-bit"
        most_recent = true
        visibility  = "public"
    }

    resource "openstack_compute_instance_v2" "instance_test" {
        name              = "server"
        count             = 3
        image_id          = data.openstack_images_image_v2.ubuntu.id
        flavor_id         = "1312"
        key_pair          = selectel_vpc_keypair_v2.keypair_1.name
        availability_zone = "ru-9a"

        network {
            port = openstack_networking_port_v2.port[count.index].id
        }

        lifecycle {
            ignore_changes = [image_id]
        }

        vendor_options {
            ignore_resize_confirmation = true
        }

    }

    resource "openstack_networking_floatingip_v2" "floatingip" {
        pool  = "external-network"
        count = 3
    }

    resource "openstack_networking_floatingip_associate_v2" "association" {
        count       = 3
        port_id     = openstack_networking_port_v2.port[count.index].id
        floating_ip = openstack_networking_floatingip_v2.floatingip[count.index].address
    }

1. optional: configure providers⁠

If you have configured Selectel and OpenStack providers, skip this step.

  1. Make sure that in the control panel you created a service user with the Account Administrator and User Administrator roles.

  2. Create a directory to store the configuration files and a separate file with the extension .tf to configure the ISPs.

  3. Add Selectel and OpenStack providers to the file to configure the providers:

    terraform {
      required_providers {
        selectel  = {
          source  = "selectel/selectel"
          version = "~> 6.0"
        }
        openstack = {
          source  = "terraform-provider-openstack/openstack"
          version = "2.1.0"
        }
      }
    }

    Here version — provider versions. The current version can be found in the Selectel documentation (in the Terraform Registry and GitHub) and OpenStack (in Terraform Registry and GitHub).

    Read more about products, services and services that can be managed with providers in the instructions Selectel and OpenStack providers.

  4. Initialize the Selectel provider:

    provider "selectel" {
      domain_name = "123456"
      username    = "user"
      password    = "password"
      auth_region = "ru-9"
      auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
    }

    Here:

    • domain_name — Selectel account number. You can look in control panels in the upper right-hand corner;
    • username — name service user with the Account Administrator and User Administrator roles. You can look in control panels: section Identity & Access Management → User management → tab Service users (the section is only available to the Account Owner and User Administrator);
    • password — service user password. You can view it when creating a user or change to a new one;
    • auth_region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

  5. Create a project:

    resource "selectel_vpc_project_v2" "project_1" {
      name = "project"
    }

    Check out the detailed description of the resource selectel_vpc_project_v2.

  6. Create a service user to access the project and assign the Project Administrator role to it:

    resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
      name         = "username"
      password     = "password"
      role {
        role_name  = "member"
        scope      = "project"
        project_id = selectel_vpc_project_v2.project_1.id 
      }
    }

    Here:

    • username — username;
    • password — user password. The password must be no shorter than eight characters and contain Latin letters of different cases and digits;
    • project_id — Project ID. You can look in control panels: section Cloud platform → open the project menu (name of the current project) → in the line of the desired project, click .

    Check out the detailed description of the resource selectel_iam_serviceuser_v1.

  7. Initialize the OpenStack provider:

    provider "openstack" {
      auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
      domain_name = "123456"
      tenant_id   = selectel_vpc_project_v2.project_1.id
      user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
      password    = selectel_iam_serviceuser_v1.serviceuser_1.password
      region      = "ru-9"
    }

    Here:

    • domain_name — Selectel account number. You can look in control panels in the upper right-hand corner;
    • region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

  8. If at the same time you are setting up your providers resource creation then for OpenStack resources add the argument depends_on. For example, for the openstack_networking_network_v2 resource:

    resource "openstack_networking_network_v2" "network_1" {
      name           = "private-network"
      admin_state_up = "true"

      depends_on = [
        selectel_vpc_project_v2.project_1,
        selectel_iam_serviceuser_v1.serviceuser_1
      ]
    }

  9. Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add a block to it:

    provider_installation {
      network_mirror {
        url = "https://tf-proxy.selectel.ru/mirror/v1/"
        include = ["registry.terraform.io/*/*"]
      }
      direct {
        exclude = ["registry.terraform.io/*/*"]
      }
    }

    Read more about mirror settings in the manual CLI Configuration File HashiCorp documentation.

  10. Open the CLI.

  11. Initialize the Terraform configuration in the directory:

    terraform init

  12. Check that the configuration files have been compiled without errors:

    terraform validate

  13. Format the configuration files:

    terraform fmt

  14. Check the resources that will be created:

    terraform plan

  15. Apply the changes and create the resources:

    terraform apply

  16. Confirm creation — enter yes and press Enter. The created resources are displayed in the control panel.

  17. If there were insufficient quotas to create resources, increase quotas.

2. Add a public SSH key⁠

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

Here. public_key — path to the public SSH key. If SSH keys are not generated, create them.

Check out the detailed description of the resource selectel_vpc_keypair_v2.

3. Create a private network and subnet⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here. cidr — CIDR of a private subnet, e.g. 192.168.199.0/24.

See a detailed description of the resources:

4. Create a cloud router connected to an external network⁠

A cloud router connected to an external network acts as a 1:1 NAT for access from a private network to the Internet through the public IP address of the router.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

See a detailed description of the resources:

5. Create ports for cloud servers⁠

resource "openstack_networking_port_v2" "port" {
  name       = "port"
  count      = 3
  network_id = openstack_networking_network_v2.network2.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_2.id
  }
}

Here. count — number of ports.

Check out the detailed description of the resource openstack_networking_port_v2.

6. Get an image⁠

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

Check out the detailed description of the data source openstack_images_image_v2.

7. Create cloud servers⁠

resource "openstack_compute_instance_v2" "instance_test" {
  name              = "server"
  count             = 3
  image_id          = data.openstack_images_image_v2.ubuntu.id
  flavor_id         = "1312"
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port[count.index].id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Here:

  • count — number of servers;
  • flavor_id — Flavor ID. For example, 1312 — The ID of the Standard Line fixed-configuration flavor c 1 vCPU, 2048 GB RAM, 16 GB local disk. The list of flavors can be viewed using the command openstack flavor list or in a table List of fixed-configuration flavorings in all pools;
  • availability_zone — pool segment in which cloud servers will be created, e.g. ru-9a. The list of available pool segments can be found in the instructions Availability matrices.

Check out the detailed description of the resource openstack_compute_instance_v2.

8. Create public IP addresses⁠

resource "openstack_networking_floatingip_v2" "floatingip" {
  count = 3  
  pool  = "external-network"
}

Here. count — number of public IP addresses.

Check out the detailed description of the resource openstack_networking_floatingip_v2.

9. Associate public and private IP addresses of cloud servers⁠

Public IP addresses will be connected to cloud server ports and associated with private IP addresses.

resource "openstack_networking_floatingip_associate_v2" "association" {
  count       = 3
  port_id     = openstack_networking_port_v2.port[count.index].id
  floating_ip = openstack_networking_floatingip_v2.floatingip[count.index].address
}

Here. count — number of associations of public and private IP addresses.

Check out the detailed description of the resource openstack_networking_floatingip_associate_v2.