Create an image and set up access to it in another project

We recommend that you create resources in order. If you create all resources at once, Terraform will take into account the dependencies between resources that you specify in the configuration file. If dependencies are not specified, resources will be created in parallel, which can cause errors. For example, a resource that is required to create another resource may not have been created yet.

Configure the providers for the source project.
Create an image.
Configure access to the image in another project.
Configure the providers for the target project.
Embrace the image in the target project.

Configuration files

Example file for configuring providers

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Sample file for creating an image and setting up access to the image for other projects

resource "openstack_images_image_v2" "image_1" {
    name             = "Debian 12.10"
    container_format = "bare"
    disk_format      = "qcow2"
    visibility       = "shared"

    properties = {
        key = "value"
    }
}

resource "openstack_images_image_access_v2" "member_1" {
    image_id  = openstack_images_image_v2.image_1.id
    member_id = "bed6b6cbb86a4e2d8dc2735c2f1000e4"
}

Sample file for adopting an image in a target project

data "openstack_images_image_v2" "image_1" {
    name          = "Debian 12.10"
    visibility    = "shared"
    member_status = "all"
}

resource "openstack_images_image_access_accept_v2" "member_1" {
    image_id = data.openstack_images_image_v2.image_1.id
    status   = "accepted"
}

1. Configure providers for the source project

If you have configured Selectel and OpenStack providers, skip this step.

Ensure that in the Control Panel you have created a service user with the Account Administrator and User Administrator roles.
Create a directory to store the configuration files and a separate file with a .tf extension to configure the providers.
Add Selectel and OpenStack providers to the file to configure the providers:
```
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Here version — versions of providers. The current version can be found in Selectel (in Terraform Registry and GitHub) and OpenStack (in Terraform Registry and GitHub) documentation.

Learn more about the products, services, and services that can be managed with providers in the Selectel and OpenStack Providers instruction.
Initialize the Selectel provider:
```
provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}
```
Here:
- domain_name — Selectel account number. You can look it up in control panel in the upper right corner;
- username — username service user with the roles Account Administrator and User Administrator. Can be viewed in the control panel section Access Control → User Management → tab Service Users (the section is available only to the Account Owner and User Administrator);
- password — password of the service user. You can view it when creating a user or change it to a new one;
- auth_region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.
Create a project:
```
resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}
```
View a detailed description of the selectel_vpc_project_v2 resource.
Create a service user to access the project and assign the Project Administrator role to it:
```
resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id
  }
}
```
Here:
- username — username;
- password — user password. The password must be no shorter than eight characters and contain Latin letters of different cases and digits;
- project_id — Project ID. You can view it in control panel: section Cloud Platform → open the projects menu (the name of the current project) → in the line of the required project press .
View a detailed description of the selectel_iam_serviceuser_v1 resource.

Initialize the OpenStack provider:

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Here:

domain_name — Selectel account number. You can look it up in control panel in the upper right corner;
region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

If you create resources at the same time as configuring providers, add the depends_on argument for OpenStack resources . For example, for the resource openstack_networking_network_v2:

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    selectel_vpc_project_v2.project_1,
    selectel_iam_serviceuser_v1.serviceuser_1
  ]
}

Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add a block to it:
```
provider_installation {
  network_mirror {
    url = "https://tf-proxy.selectel.ru/mirror/v1/"
    include = ["registry.terraform.io/*/*"]
  }
  direct {
    exclude = ["registry.terraform.io/*/*"]
  }
}
```
See the CLI Configuration File instructions in HashiCorp's CLI Configuration File documentation for more information on configuring mirrors.
Open the CLI.
Initialize the Terraform configuration in the directory:
```
terraform init
```
Check that the configuration files have been compiled without errors:
```
terraform validate
```
Format the configuration files:
```
terraform fmt
```
Check the resources that will be created:
```
terraform plan
```
Apply the changes and create the resources:
```
terraform apply
```
Confirm the creation — type yes and press Enter. The created resources are displayed in the control panel.
If there were not enough quotas to create resources, increase the quotas.

2. Create an image

resource "openstack_images_image_v2" "image_1" {
    name             = "Debian 12.10"
    container_format = "bare"
    disk_format      = "qcow2"
    visibility       = "shared"

    properties = {
        key = "value"
    }
}

Here:

container_format — container format. The available values are ami, ari, aki, bare, ovf;
disk_format — the disk format of the image. The available values are. ami, ari, aki, vhd, vmdk, raw, vhd, vmdk, vhd, qcow2, vdi, iso;
visibility = "shared" — image can be added to other projects.

Check out the detailed description of the openstack_images_image_v2 resource.

3. Configure access to the image in the source project

resource "openstack_images_image_access_v2" "member_1" {
    image_id  = openstack_images_image_v2.image_1.id
    member_id = "bed6b6cbb86a4e2d8dc2735c2f1000e4"
}

Here member_id is the ID of the target project. You can view it in the control panel: in the top menu click Products → Cloud Servers → open the projects menu → in the line of the required project click .

See the detailed description of the openstack_images_image_access_v2 resource.

4. Configure providers for the target project

Create a separate configuration file and configure the providers under the account and project for which you have configured image access.

Ensure that in the Control Panel you have created a service user with the Account Administrator and User Administrator roles.
Create a directory to store the configuration files and a separate file with a .tf extension to configure the providers.
Add Selectel and OpenStack providers to the file to configure the providers:
```
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Here version — versions of providers. The current version can be found in Selectel (in Terraform Registry and GitHub) and OpenStack (in Terraform Registry and GitHub) documentation.

Learn more about the products, services, and services that can be managed with providers in the Selectel and OpenStack Providers instruction.
Initialize the Selectel provider:
```
provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}
```
Here:
- domain_name — Selectel account number. You can look it up in control panel in the upper right corner;
- username — username service user with the roles Account Administrator and User Administrator. Can be viewed in the control panel section Access Control → User Management → tab Service Users (the section is available only to the Account Owner and User Administrator);
- password — password of the service user. You can view it when creating a user or change it to a new one;
- auth_region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.
Create a project:
```
resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}
```
View a detailed description of the selectel_vpc_project_v2 resource.
Create a service user to access the project and assign the Project Administrator role to it:
```
resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id
  }
}
```
Here:
- username — username;
- password — user password. The password must be no shorter than eight characters and contain Latin letters of different cases and digits;
- project_id — Project ID. You can view it in control panel: section Cloud Platform → open the projects menu (the name of the current project) → in the line of the required project press .
View a detailed description of the selectel_iam_serviceuser_v1 resource.

Initialize the OpenStack provider:

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Here:

domain_name — Selectel account number. You can look it up in control panel in the upper right corner;
region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

If you create resources at the same time as configuring providers, add the depends_on argument for OpenStack resources . For example, for the resource openstack_networking_network_v2:

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    selectel_vpc_project_v2.project_1,
    selectel_iam_serviceuser_v1.serviceuser_1
  ]
}

Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add a block to it:
```
provider_installation {
  network_mirror {
    url = "https://tf-proxy.selectel.ru/mirror/v1/"
    include = ["registry.terraform.io/*/*"]
  }
  direct {
    exclude = ["registry.terraform.io/*/*"]
  }
}
```
See the CLI Configuration File instructions in HashiCorp's CLI Configuration File documentation for more information on configuring mirrors.
Open the CLI.
Initialize the Terraform configuration in the directory:
```
terraform init
```
Check that the configuration files have been compiled without errors:
```
terraform validate
```
Format the configuration files:
```
terraform fmt
```
Check the resources that will be created:
```
terraform plan
```
Apply the changes and create the resources:
```
terraform apply
```
Confirm the creation — type yes and press Enter. The created resources are displayed in the control panel.
If there were not enough quotas to create resources, increase the quotas.

5. Take an image in the target project

data "openstack_images_image_v2" "image_1" {
    name          = "Debian 12.10"
    visibility    = "shared"
    member_status = "all"
}

resource "openstack_images_image_access_accept_v2" "member_1" {
    image_id = data.openstack_images_image_v2.image_1.id
    status   = "accepted"
}

Here status = "accepted" — the image will be accepted in the target project.

View the detailed resource description of openstack_images_image_access_accept_v2.