Создать базовый кластер Managed Kubernetes

Последнее изменение: 27 августа 2024

Создать базовый кластер Managed Kubernetes

Мы рекомендуем создавать ресурсы по порядку. Если вы единовременно создаете все ресурсы, которые описаны в конфигурационном файле, может возникнуть ошибка — Terraform создает ресурсы независимо от порядка, в котором они перечислены в файле.

1. Опционально: настройте провайдеры.
2. Создайте приватную сеть и подсеть.
3. Создайте облачный роутер, подключенный к внешней сети.
4. Создайте базовый кластер.
5. Создайте группу нод с сетевым диском.

Конфигурационные файлы⁠

Пример файла для настройки провайдеров

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "6.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Пример файла для базового кластера с нодами произвольной конфигурации

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

data "selectel_mks_kube_versions_v1" "versions" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
}

resource "selectel_mks_cluster_v1" "cluster_1" {
  name                              = "basic_cluster"
  project_id                        = selectel_vpc_project_v2.project_1.id
  region                            = "ru-9"
  kube_version                      = data.selectel_mks_kube_versions_v1.versions.latest_version
  zonal                             = true
  enable_patch_version_auto_upgrade = false
  network_id                        = openstack_networking_network_v2.network_1.id
  subnet_id                         = openstack_networking_subnet_v2.subnet_1.id
  maintenance_window_start          = "00:00:00"
}

resource "selectel_mks_nodegroup_v1" "nodegroup_1" {
  cluster_id        = selectel_mks_cluster_v1.cluster_1.id
  project_id        = selectel_mks_cluster_v1.cluster_1.project_id
  region            = selectel_mks_cluster_v1.cluster_1.region
  availability_zone = "ru-9a"
  nodes_count       = "2"
  cpus              = 2
  ram_mb            = 4096
  volume_gb         = 32
  volume_type       = "fast.ru-9a"
  labels            = {
    "label-key0": "label-value0",
    "label-key1": "label-value1",
    "label-key2": "label-value2",
  }
}

Пример файла для базового кластера с нодами фиксированной конфигурации (флейворами)

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

data "selectel_mks_kube_versions_v1" "versions" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
}

resource "selectel_mks_cluster_v1" "cluster_1" {
  name                              = "basic_cluster"
  project_id                        = selectel_vpc_project_v2.project_1.id
  region                            = "ru-9"
  kube_version                      = data.selectel_mks_kube_versions_v1.versions.latest_version
  zonal                             = true
  enable_patch_version_auto_upgrade = false
  network_id                        = openstack_networking_network_v2.network_1.id
  subnet_id                         = openstack_networking_subnet_v2.subnet_1.id
  maintenance_window_start          = "00:00:00"
}

resource "selectel_mks_nodegroup_v1" "nodegroup_1" {
  cluster_id        = selectel_mks_cluster_v1.cluster_1.id
  project_id        = selectel_mks_cluster_v1.cluster_1.project_id
  region            = selectel_mks_cluster_v1.cluster_1.region
  availability_zone = "ru-9a"
  nodes_count       = "2"
  flavor_id         = "1011"
  volume_gb         = 32
  volume_type       = "fast.ru-9a"
  labels            = {
    "label-key0": "label-value0",
    "label-key1": "label-value1",
    "label-key2": "label-value2",
  }
}

1. Опционально: настроить провайдеры⁠

Если вы настроили провайдеры Selectel и OpenStack, пропустите этот шаг.

1. Убедитесь, что в панели управления вы создали сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей.

2. Создайте директорию для хранения конфигурационных файлов и отдельный файл с расширением .tf для настройки провайдеров.

3. В файл для настройки провайдеров добавьте провайдеры Selectel и OpenStack:

   terraform {
     required_providers {
       selectel  = {
         source  = "selectel/selectel"
         version = "6.0.0"
       }
       openstack = {
         source  = "terraform-provider-openstack/openstack"
         version = "2.1.0"
       }
     }
   }

   Здесь version — версии провайдеров. Актуальную версию можно посмотреть в документации Selectel (в Terraform Registry и GitHub) и OpenStack (в Terraform Registry и GitHub).

   Подробнее о продуктах, услугах и сервисах, которыми можно управлять с помощью провайдеров, в инструкции Провайдеры Selectel и OpenStack.

4. Инициализируйте провайдер Selectel:

   provider "selectel" {
     domain_name = "123456"
     username    = "user"
     password    = "password"
   }

   Здесь:

   • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
   • username — имя сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей. Можно посмотреть в панели управления: раздел Управление доступом → Управление пользователями → вкладка Сервисные пользователи (раздел доступен только Владельцу аккаунта и Администратору пользователей);
   • password — пароль сервисного пользователя. Можно посмотреть при создании пользователя или изменить на новый.

5. Создайте проект:

   resource "selectel_vpc_project_v2" "project_1" {
     name = "project"
   }

   Посмотрите подробное описание ресурса selectel_vpc_project_v2.

6. Создайте сервисного пользователя для доступа к проекту и назначьте ему роль Администратор проекта:

   resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
     name         = "username"
     password     = "password"
     role {
       role_name  = "member"
       scope      = "project"
       project_id = selectel_vpc_project_v2.project_1.id 
     }
   }

   Здесь:

   • username — имя пользователя;
   • password — пароль пользователя. Пароль должен быть не короче восьми символов и содержать латинские буквы разных регистров и цифры;
   • project_id — ID проекта. Можно посмотреть в панели управления: раздел Облачная платформа → откройте меню проектов (название текущего проекта) → в строке нужного проекта нажмите .

   Посмотрите подробное описание ресурса selectel_iam_serviceuser_v1.

7. Инициализируйте провайдер OpenStack:

   provider "openstack" {
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
     domain_name = "123456"
     tenant_id   = selectel_vpc_project_v2.project_1.id
     user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
     password    = selectel_iam_serviceuser_v1.serviceuser_1.password
     region      = "ru-9"
   }

   Здесь:

   • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
   • region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

8. Если одновременно с настройкой провайдеров вы создаете ресурсы, то для ресурсов OpenStack добавьте аргумент depends_on. Например, для ресурса openstack_networking_network_v2:

   resource "openstack_networking_network_v2" "network_1" {
     name           = "private-network"
     admin_state_up = "true"
   
     depends_on = [
       selectel_vpc_project_v2.project_1,
       selectel_iam_serviceuser_v1.serviceuser_1
     ]
   }

9. Опционально: если вы хотите использовать зеркало, создайте отдельный конфигурационный файл Terraform CLI и добавьте в него блок:

   provider_installation {
     network_mirror {
       url = "https://tf-proxy.selectel.ru/mirror/v1/"
       include = ["registry.terraform.io/*/*"]
     }
     direct {
       exclude = ["registry.terraform.io/*/*"]
     }
   }

   Подробнее о настройках зеркал в инструкции CLI Configuration File документации HashiCorp.

10. Откройте CLI.

11. Инициализируйте конфигурацию Terraform в директории:

    terraform init

12. Проверьте, что конфигурационные файлы составлены без ошибок:

    terraform validate

13. Отформатируйте конфигурационные файлы:

    terraform fmt

14. Проверьте, какие ресурсы будут созданы:

    terraform plan

15. Примените изменения и создайте ресурсы:

    terraform apply

16. Подтвердите создание — введите yes и нажмите Enter. Созданные ресурсы отобразятся в панели управления.

17. Если для создания ресурсов оказалось недостаточно квот, увеличьте квоты.

2. Создать приватную сеть и подсеть⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name            = "private-subnet"
  network_id      = openstack_networking_network_v2.network_1.id
  cidr            = "192.168.199.0/24"
  dns_nameservers = ["188.93.16.19", "188.93.17.19"]
  enable_dhcp     = false
}

Здесь:

• cidr — CIDR приватной подсети, например 192.168.199.0/24;
• dns_nameservers — DNS-серверы, например DNS Selectel 188.93.16.19 и 188.93.17.19.

Посмотрите подробное описание ресурсов:

• openstack_networking_network_v2;
• openstack_networking_subnet_v2.

3. Создать облачный роутер, подключенный к внешней сети⁠

Облачный роутер, подключенный к внешней сети, выполняет функцию 1:1 NAT для доступа из приватной сети в интернет через публичный IP-адрес роутера.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

Посмотрите подробное описание ресурсов:

• openstack_networking_network_v2;
• openstack_networking_router_v2;
• openstack_networking_router_interface_v2.

4. Создать базовый кластер⁠

data "selectel_mks_kube_versions_v1" "versions" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
}

resource "selectel_mks_cluster_v1" "cluster_1" {
  name                              = "basic_cluster"
  project_id                        = selectel_vpc_project_v2.project_1.id
  region                            = "ru-9"
  kube_version                      = data.selectel_mks_kube_versions_v1.versions.latest_version
  zonal                             = true
  enable_patch_version_auto_upgrade = false
  network_id                        = openstack_networking_network_v2.network_1.id
  subnet_id                         = openstack_networking_subnet_v2.subnet_1.id
  maintenance_window_start          = "00:00:00"
}

Здесь region — пул, например ru-9. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

Посмотрите подробное описание ресурса selectel_mks_cluster_v1.

5. Создать группу нод с сетевым диском⁠

Фиксированная конфигурация

resource "selectel_mks_nodegroup_v1" "nodegroup_1" {
  cluster_id        = selectel_mks_cluster_v1.cluster_1.id
  project_id        = selectel_mks_cluster_v1.cluster_1.project_id
  region            = selectel_mks_cluster_v1.cluster_1.region
  availability_zone = "ru-9a"
  nodes_count       = "2"
  flavor_id         = "1011"
  volume_gb         = 32
  volume_type       = "fast.ru-9a"
  labels            = {
    "label-key0": "label-value0",
    "label-key1": "label-value1",
    "label-key2": "label-value2",
  }
}

Здесь:

• availability_zone — сегмент пула, в котором будет находиться группа нод, например ru-9a;
• nodes_count — количество рабочих нод в группе нод. Максимальное количество нод — 15;
• flavor_id — ID флейвора. Флейворы соответствуют конфигурациям облачного сервера и определяют количество vCPU, RAM и размер локального диска (опционально) ноды. Например, 3031 — флейвор для создания ноды с конфигурацией линейки GPU Line с 4 vCPU, 32 ГБ RAM. Вы можете посмотреть список флейворов в определенном пуле в Openstack CLI;
• volume_gb — размер диска в ГБ. Если размер диска указан в конфигурации, которую вы выбрали в аргументе flavor_id, то аргумент volume_gb не нужно указывать;
• volume_type — тип диска в формате <type>.<pool_segment>, например basic.ru-9a:
  • <type> — basic, universal или fast;
  • <pool_segment> — сегмент пула, в котором будет создан сетевой диск, например ru-9a.

Посмотрите подробное описание ресурса selectel_mks_nodegroup_v1.

Произвольная конфигурация

resource "selectel_mks_nodegroup_v1" "nodegroup_1" {
  cluster_id        = selectel_mks_cluster_v1.cluster_1.id
  project_id        = selectel_mks_cluster_v1.cluster_1.project_id
  region            = selectel_mks_cluster_v1.cluster_1.region
  availability_zone = "ru-9a"
  nodes_count       = "2"
  cpus              = 2
  ram_mb            = 4096
  volume_gb         = 32
  volume_type       = "fast.ru-9a"
  labels            = {
    "label-key0": "label-value0",
    "label-key1": "label-value1",
    "label-key2": "label-value2",
  }
}

Здесь:

• availability_zone — сегмент пула, в котором будет находиться группа нод, например ru-9a;
• nodes_count — количество рабочих нод в группе нод. Максимальное количество нод — 15;
• cpus — количество vCPU для каждой ноды;
• ram_mb — количество RAM для каждой ноды в МБ;
• volume_gb — размер диска в ГБ;
• volume_type — тип диска в формате <type>.<pool_segment>, например basic.ru-9a:
  • <type> — basic, universal или fast;
  • <pool_segment> — сегмент пула, в котором будет создан сетевой диск, например ru-9a.

Посмотрите подробное описание ресурса selectel_mks_nodegroup_v1.