Create a server on a public subnet | Selectel Documentation

Create a cloud server on a public subnet

We recommend create resources in order. If you create all the resources that are described in the configuration file The Terraform creates resources regardless of the order in which they are listed in the file.

Configuration files⁠

Example file for configuring providers

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "6.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "pool"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Sample file for creating a cloud server on a public subnet

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

resource "selectel_vpc_subnet_v2" "subnet_1" {
  project_id    = selectel_vpc_project_v2.project_1.id
  region        = "ru-9"
  ip_version    = "ipv4"
  prefix_length = 29
}

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = selectel_vpc_subnet_v2.subnet_1.network_id

  fixed_ip {
    subnet_id = selectel_vpc_subnet_v2.subnet_1.subnet_id
  }
}

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.ru-9a"
  availability_zone    = "ru-9a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = "4011"
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

output "public_ip_address" {
  value = openstack_compute_instance_v2.server_1.access_ip_v4
}

optional: configure providers⁠

If you're set up the ISPs Selectel and OpenStack, skip this step.

Make sure that in the control panel you created a service user with the Account Administrator and User Administrator roles.
Create a directory to store the configuration files and a separate file with the extension .tf to configure the ISPs.
Add Selectel and OpenStack providers to the file to configure the providers:
```
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "6.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Here version — provider versions. The current version can be found in the Selectel documentation (in the Terraform Registry and GitHub) and OpenStack (in Terraform Registry and GitHub).

Read more about products, services and services that can be managed with providers in the instructions Selectel and OpenStack providers.
Initialize the Selectel provider:
```
provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "pool"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}
```
Here:
- domain_name — Selectel account number. You can look in control panels in the upper right-hand corner;
- username — name service user with the Account Administrator and User Administrator roles. You can look in control panels: section Identity & Access Management → User management → tab Service users (the section is only available to the Account Owner and User Administrator);
- password — service user password. You can view it when creating a user or change to a new one.
Create a project:
```
resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}
```
Check out the detailed description of the resource selectel_vpc_project_v2.
Create a service user to access the project and assign the Project Administrator role to it:
```
resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}
```
Here:
- username — username;
- password — user password. The password must be no shorter than eight characters and contain Latin letters of different cases and digits;
- project_id — Project ID. You can look in control panels: section Cloud platform → open the project menu (name of the current project) → in the line of the desired project, click .
Check out the detailed description of the resource selectel_iam_serviceuser_v1.

Initialize the OpenStack provider:

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Here:

domain_name — Selectel account number. You can look in control panels in the upper right-hand corner;
region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

If at the same time you are setting up your providers resource creation then for OpenStack resources add the argument depends_on. For example, for the openstack_networking_network_v2 resource:

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    selectel_vpc_project_v2.project_1,
    selectel_iam_serviceuser_v1.serviceuser_1
  ]
}

Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add a block to it:

provider_installation {
  network_mirror {
    url = "https://tf-proxy.selectel.ru/mirror/v1/"
    include = ["registry.terraform.io/*/*"]
  }
  direct {
    exclude = ["registry.terraform.io/*/*"]
  }
}

Read more about mirror settings in the manual CLI Configuration File HashiCorp documentation.

Open the CLI.
Initialize the Terraform configuration in the directory:
```
terraform init
```
Check that the configuration files have been compiled without errors:
```
terraform validate
```
Format the configuration files:
```
terraform fmt
```
Check the resources that will be created:
```
terraform plan
```
Apply the changes and create the resources:
```
terraform apply
```
Confirm creation — enter yes and press Enter. The created resources are displayed in the control panel.
If there were insufficient quotas to create resources, increase quotas.

Create an SSH key pair⁠

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

Here. public_key — path to the public SSH key. If SSH keys have not been created, generate them.

Check out the detailed description of the resource selectel_vpc_keypair_v2.

Create a public subnet⁠

resource "selectel_vpc_subnet_v2" "subnet_1" {
  project_id    = selectel_vpc_project_v2.project_1.id
  region        = "ru-9"
  ip_version    = "ipv4"
  prefix_length = 29
}

Here. region — the pool in which the public subnet will be created, e.g. ru-9. The list of available pools can be found in the instructions Availability matrix.

Check out the detailed description of the resource selectel_vpc_subnet_v2.

Create a port for the cloud server⁠

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = selectel_vpc_subnet_v2.subnet_1.network_id

  fixed_ip {
    subnet_id = selectel_vpc_subnet_v2.subnet_1.subnet_id
  }
}

Check out the detailed description of the resource openstack_networking_port_v2.

Get an image⁠

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

Check out the detailed description of the data source openstack_images_image_v2.

Create a bootable network disk⁠

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.ru-9a"
  availability_zone    = "ru-9a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

Here:

size — disk size in GB. Consider network disk limits to the maximum size;
volume_type — ID or name network drive type. For example, fast.ru-9a — name to create a network drive with the SSD type Fast in the pool segment ru-9a. The list of types can be seen in the table List of network disk types in all pool segments;
availability_zone — pool segment where the network drive will be created, e.g. ru-9a. The list of available pool segments can be found in the instructions Availability matrix.

Check out the detailed description of the resource openstack_blockstorage_volume_v3.

Create a cloud server⁠

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = "4011"
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Here:

availability_zone — pool segment where the cloud server will be created, e.g. ru-9a. The list of available pool segments can be found in the instructions Availability matrix;
flavor_id — Flavor ID. The flavors correspond to cloud server configurations and determine the number of vCPUs, RAM and local disk size (optional) of the server. You can use fixed configuration flavors. For example, 4011 — ID to create a Memory Line fixed-configuration server with 2 vCPUs, 16 GB RAM in a ru-9 pool. The list of flavors can be viewed in the table List of fixed-configuration flavorings in all pools.

Check out the detailed description of the resource openstack_compute_instance_v2.

Get the IP address of the cloud server⁠

output "public_ip_address" {
  value = openstack_compute_instance_v2.server_1.access_ip_v4
}

Create a cloud server on a public subnet

Configuration files⁠​

optional: configure providers⁠​

Create an SSH key pair⁠​

Create a public subnet⁠​

Create a port for the cloud server⁠​

Get an image⁠​

Create a bootable network disk⁠​

Create a cloud server⁠​

Get the IP address of the cloud server⁠​

Configuration files⁠

optional: configure providers⁠

Create an SSH key pair⁠

Create a public subnet⁠

Create a port for the cloud server⁠

Get an image⁠

Create a bootable network disk⁠

Create a cloud server⁠

Get the IP address of the cloud server⁠