Skip to main content

Create a fault-tolerant Managed Kubernetes cluster via Terraform

We recommend creating resources sequentially. If you create all resources at the same time, Terraform will take into account the dependencies between resources that you specified in the configuration file. If dependencies are not specified, resources will be created in parallel, which may lead to errors. For example, a resource required to create another resource may not be created yet.


  1. Optional: configure providers.
  2. Create a private network and subnet.
  3. Create an internet-connected cloud router.
  4. Create a high-availability cluster.
  5. Create a node group with a network drive.

Configuration files

Example file for configuring providers
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}
Example file for a fault-tolerant cluster with nodes of custom configuration
resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

data "selectel_mks_kube_versions_v1" "versions" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
}

resource "selectel_mks_cluster_v1" "cluster_1" {
  name                     = "high-availability-cluster"
  project_id               = selectel_vpc_project_v2.project_1.id
  region                   = "ru-9"
  kube_version             = data.selectel_mks_kube_versions_v1.versions.latest_version
  network_id               = openstack_networking_network_v2.network_1.id
  subnet_id                = openstack_networking_subnet_v2.subnet_1.id
  maintenance_window_start = "00:00:00"
}

resource "selectel_mks_nodegroup_v1" "nodegroup_1" {
  cluster_id                   = selectel_mks_cluster_v1.cluster_1.id
  project_id                   = selectel_mks_cluster_v1.cluster_1.project_id
  region                       = selectel_mks_cluster_v1.cluster_1.region
  availability_zone            = "ru-9a"
  nodes_count                  = "2"
  cpus                         = 2
  ram_mb                       = 4096
  volume_gb                    = 32
  volume_type                  = "fast.ru-9a"
  install_nvidia_device_plugin = false
  labels                       = {
    "label-key0": "label-value0",
    "label-key1": "label-value1",
    "label-key2": "label-value2",
  }
}
Example file for a fault-tolerant cluster with nodes of a fixed configuration (flavors)
resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

data "selectel_mks_kube_versions_v1" "versions" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
}

resource "selectel_mks_cluster_v1" "cluster_1" {
  name                     = "high-availability-cluster"
  project_id               = selectel_vpc_project_v2.project_1.id
  region                   = "ru-9"
  kube_version             = data.selectel_mks_kube_versions_v1.versions.latest_version
  network_id               = openstack_networking_network_v2.network_1.id
  subnet_id                = openstack_networking_subnet_v2.subnet_1.id
  maintenance_window_start = "00:00:00"
}

resource "selectel_mks_nodegroup_v1" "nodegroup_1" {
  cluster_id                   = selectel_mks_cluster_v1.cluster_1.id
  project_id                   = selectel_mks_cluster_v1.cluster_1.project_id
  region                       = selectel_mks_cluster_v1.cluster_1.region
  availability_zone            = "ru-9a"
  nodes_count                  = "2"
  flavor_id                    = "1013"
  volume_gb                    = 32
  volume_type                  = "fast.ru-9a"
  install_nvidia_device_plugin = false
  labels                       = {
    "label-key0": "label-value0",
    "label-key1": "label-value1",
    "label-key2": "label-value2",
  }
}

1. Optional: configure providers

If you have configured the Selectel and OpenStack providers, skip this step.

  1. Make sure that in the control panel you have created a service user with the member roles in the Account scope and iam.admin.

  2. Create a directory to store configuration files and a separate file with the .tf extension to configure providers.

  3. Add the Selectel and OpenStack providers to the file for provider configuration:

    terraform {
      required_providers {
        selectel  = {
          source  = "selectel/selectel"
          version = "~> 7.1.0"
        }
        openstack = {
          source  = "terraform-provider-openstack/openstack"
          version = "2.1.0"
        }
      }
    }

    Here version is provider versions. You can check the current version in the Selectel documentation (in the Terraform Registry and GitHub) and OpenStack (in the Terraform Registry and GitHub).

    For more information about products, services, and features that can be managed using providers, see the Selectel and OpenStack Providers instructions.

  4. Initialize the Selectel provider:

    provider "selectel" {
      domain_name = "123456"
      username    = "user"
      password    = "password"
      auth_region = "ru-9"
      auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
    }

    Where:

    • domain_name — Selectel account number. You can find it in the control panel in the upper-right corner;
    • username — name of the service user with the member roles in the Account scope and iam.admin. You can find it in the control panel: in the top menu, click IAM → Service Users (the section is available only to the Account Owner and a user with the iam.admin role);
    • password — password of the service user. You can view it when creating the user or change it to a new one;
    • auth_region — pool for authorization in the ru-9 format; do not use pools in the SPB-2 format. The pool for authorization may differ from the pool where you create resources. You can check the list of available pools in the Product Availability by Location instructions.

  5. Create a project:

    resource "selectel_vpc_project_v2" "project_1" {
      name = "project"
    }

    See the detailed description of the selectel_vpc_project_v2 resource.

  6. Create a service user to access the project and assign them the member role in the Project scope:

    resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
      name         = "username"
      password     = "password"
      role {
        role_name  = "member"
        scope      = "project"
        project_id = selectel_vpc_project_v2.project_1.id
      }
    }

    Where:

    • username — username;

    • password — user password. The password must be at least 20 characters long and include at least:

      • one uppercase and one lowercase Latin letter (A-Z, a-z);
      • one digit (0-9);
      • one special character from the ASCII Printable 7-Bit Special Characters list:
        !"#$%&'()*+,-./:;<=>?@[]^_{|}~;

    • project_id — project ID. You can find it in the control panel: in the top menu, click IAM → Projects → in the row of the desired project, click .

    See the detailed description of the selectel_iam_serviceuser_v1 resource.

  7. Initialize the OpenStack provider:

    provider "openstack" {
      auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
      domain_name = "123456"
      tenant_id   = selectel_vpc_project_v2.project_1.id
      user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
      password    = selectel_iam_serviceuser_v1.serviceuser_1.password
      region      = "ru-9"
    }

    Where:

    • domain_name — Selectel account number. You can find it in the control panel in the upper-right corner;
    • region — pool, for example, ru-9. All resources will be created in this pool. You can check the list of available pools in the Product Availability by Location instructions.

  8. If you create resources at the same time as configuring providers, add the depends_on argument for OpenStack resources. For example, for the openstack_networking_network_v2 resource:

    resource "openstack_networking_network_v2" "network_1" {
      name           = "private-network"
      admin_state_up = "true"

      depends_on = [
        selectel_vpc_project_v2.project_1,
        selectel_iam_serviceuser_v1.serviceuser_1
      ]
    }

  9. Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add the following block to it:

    provider_installation {
      network_mirror {
        url = "https://tf-proxy.selectel.ru/mirror/v1/"
        include = ["registry.terraform.io/*/*"]
      }
      direct {
        exclude = ["registry.terraform.io/*/*"]
      }
    }

    For more information about mirror settings, see the CLI Configuration File instructions in the HashiCorp documentation.

  10. Open the CLI.

  11. Initialize the Terraform configuration in the directory:

    terraform init

  12. Verify that the configuration files are syntactically correct:

    terraform validate

  13. Format the configuration files:

    terraform fmt

  14. Check which resources will be created:

    terraform plan

  15. Apply the changes and create the resources:

    terraform apply

  16. Confirm the creation — enter yes and press Enter. The created resources will appear in the control panel.

  17. If there are not enough quotas to create resources, increase quotas.

2. Create a private network and a subnet

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name            = "private-subnet"
  network_id      = openstack_networking_network_v2.network_1.id
  cidr            = "192.168.199.0/24"
  dns_nameservers = ["188.93.16.19", "188.93.17.19"]
  enable_dhcp     = false
}

Where:

  • cidr — CIDR of the private subnet, for example 192.168.199.0/24. You can choose any addressing that does not overlap with the 10.10.0.0/16, 10.96.0.0/12, 10.250.0.0/16 and 10.251.0.0/24 ranges. These ranges are used for internal Managed Kubernetes addressing;
  • dns_nameservers — DNS servers, for example Selectel DNS 188.93.16.19 and 188.93.17.19.

See the detailed resource description:

3. Create a cloud router connected to the internet

A cloud router connected to the internet performs 1:1 NAT for access from a private network to the internet via the router's external IP address.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

See the detailed resource description:

4. Create a fault-tolerant cluster

data "selectel_mks_kube_versions_v1" "versions" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
}

resource "selectel_mks_cluster_v1" "cluster_1" {
  name                     = "high-availability-cluster"
  project_id               = selectel_vpc_project_v2.project_1.id
  region                   = "ru-9"
  kube_version             = data.selectel_mks_kube_versions_v1.versions.latest_version
  network_id               = openstack_networking_network_v2.network_1.id
  subnet_id                = openstack_networking_subnet_v2.subnet_1.id
  maintenance_window_start = "00:00:00"
}

Where:

  • name — cluster name, up to 32 characters: Latin letters, numbers, and hyphens;

  • region — pool where the cluster will be created, for example, ru-9. You can view the list of available pools in the Product availability by location instructions.

See the detailed description of the selectel_mks_cluster_v1 resource.

5. Create a node group with a network volume

resource "selectel_mks_nodegroup_v1" "nodegroup_1" {
  cluster_id                   = selectel_mks_cluster_v1.cluster_1.id
  project_id                   = selectel_mks_cluster_v1.cluster_1.project_id
  region                       = selectel_mks_cluster_v1.cluster_1.region
  availability_zone            = "ru-9a"
  nodes_count                  = "2"
  flavor_id                    = "1013"
  volume_gb                    = 32
  volume_type                  = "fast.ru-9a"
  install_nvidia_device_plugin = false
  labels                       = {
    "label-key0": "label-value0",
    "label-key1": "label-value1",
    "label-key2": "label-value2",
  }
}

Where:

  • availability_zone — pool segment where the node group will be located, for example, ru-9a;

  • nodes_count — number of worker nodes in the node group. The maximum number of nodes is 15;

  • flavor_id — flavor ID. Flavors correspond to cloud server configurations and determine the number of vCPUs, RAM, and local drive size (optional) of the node. For example, 3031 is a flavor for creating a node with a GPU Line configuration with 4 vCPUs and 32 GB RAM. You can view the list of flavors in a specific pool in the OpenStack CLI;

  • volume_gb — disk size in GB. If the disk size is specified in the configuration you selected in the flavor_id argument, the volume_gb argument is not required. You can view the limits of available values in the Comparing node configurations on a cloud server table;

  • volume_type — disk type in the <type>.<pool_segment> format, for example, basic.ru-9a:

    • <type> — basic, universal, or fast;
    • <pool_segment> — pool segment where the network drive will be created, for example, ru-9a;

  • install_nvidia_device_plugin — confirms or cancels the installation of GPU drivers and NVIDIA® Device Plugin:

    • true — for flavors with GPU, confirms the installation of GPU drivers and NVIDIA® Device Plugin;
    • false — for flavors with and without GPU, cancels the installation of GPU drivers and NVIDIA® Device Plugin. You can manually install drivers for node groups with GPU.

See the detailed description of the selectel_mks_nodegroup_v1 resource.