Create file storage

We recommend create resources in order. If you create all the resources that are described in the configuration file The Terraform creates resources regardless of the order in which they are listed in the file.

Configuration files⁠

Example file for configuring providers

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Sample file for creating a file storage

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

resource "openstack_sharedfilesystem_sharenetwork_v2" "sharenetwork_1" {
  name              = "share-network"
  neutron_net_id    = openstack_networking_network_v2.network_1.id
  neutron_subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

resource "openstack_sharedfilesystem_share_v2" "share_1" {
  name             = "nfs-storage"
  share_type       = "basic.ru-9a"
  share_proto      = "NFS"
  size             = 50
  share_network_id = openstack_sharedfilesystem_sharenetwork_v2.sharenetwork_1.id
  metadata         = {"ip": "192.168.199.3"}
}

resource "openstack_sharedfilesystem_share_access_v2" "shareaccess_1" {
  access_level = "rw"
  access_to    = "0.0.0.0/0"
  access_type  = "ip"
  share_id     = openstack_sharedfilesystem_share_v2.share_1.id
}

1. optional: configure providers⁠

If you're set up the ISPs Selectel and OpenStack, skip this step.

Make sure that in the control panel you created a service user with the Account Administrator and User Administrator roles.
Create a directory to store the configuration files and a separate file with the extension .tf to configure the ISPs.
Add Selectel and OpenStack providers to the file to configure the providers:
```
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Here version — provider versions. The current version can be found in the Selectel documentation (in the Terraform Registry and GitHub) and OpenStack (in Terraform Registry and GitHub).

Read more about products, services and services that can be managed with providers in the instructions Selectel and OpenStack providers.
Initialize the Selectel provider:
```
provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}
```
Here:
- domain_name — Selectel account number. You can look in control panels in the upper right-hand corner;
- username — name service user with the Account Administrator and User Administrator roles. You can look in control panels: section Identity & Access Management → User management → tab Service users (the section is only available to the Account Owner and User Administrator);
- password — service user password. You can view it when creating a user or change to a new one;
- auth_region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.
Create a project:
```
resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}
```
Check out the detailed description of the resource selectel_vpc_project_v2.
Create a service user to access the project and assign the Project Administrator role to it:
```
resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}
```
Here:
- username — username;
- password — user password. The password must be no shorter than eight characters and contain Latin letters of different cases and digits;
- project_id — Project ID. You can look in control panels: section Cloud platform → open the project menu (name of the current project) → in the line of the desired project, click .
Check out the detailed description of the resource selectel_iam_serviceuser_v1.

Initialize the OpenStack provider:

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Here:

domain_name — Selectel account number. You can look in control panels in the upper right-hand corner;
region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

If at the same time you are setting up your providers resource creation then for OpenStack resources add the argument depends_on. For example, for the openstack_networking_network_v2 resource:

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    selectel_vpc_project_v2.project_1,
    selectel_iam_serviceuser_v1.serviceuser_1
  ]
}

Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add a block to it:

provider_installation {
  network_mirror {
    url = "https://tf-proxy.selectel.ru/mirror/v1/"
    include = ["registry.terraform.io/*/*"]
  }
  direct {
    exclude = ["registry.terraform.io/*/*"]
  }
}

Read more about mirror settings in the manual CLI Configuration File HashiCorp documentation.

Open the CLI.
Initialize the Terraform configuration in the directory:
```
terraform init
```
Check that the configuration files have been compiled without errors:
```
terraform validate
```
Format the configuration files:
```
terraform fmt
```
Check the resources that will be created:
```
terraform plan
```
Apply the changes and create the resources:
```
terraform apply
```
Confirm creation — enter yes and press Enter. The created resources are displayed in the control panel.
If there were insufficient quotas to create resources, increase quotas.

2. Create a private network and subnet⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here. cidr — CIDR of a private subnet, e.g. 192.168.199.0/24.

See a detailed description of the resources:

3. configure the storage network configuration⁠

resource "openstack_sharedfilesystem_sharenetwork_v2" "sharenetwork_1" {
  name              = "share-network"
  neutron_net_id    = openstack_networking_network_v2.network_1.id
  neutron_subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

Check out the detailed description of the resource openstack_sharedfilesystem_sharenetwork_v2.

4. Create file storage⁠

resource "openstack_sharedfilesystem_share_v2" "share_1" {
  name             = "nfs-storage"
  share_type       = "basic.ru-9a"
  share_proto      = "NFS"
  size             = 50
  share_network_id = openstack_sharedfilesystem_sharenetwork_v2.sharenetwork_1.id
  metadata         = {"ip": "192.168.199.3"}
}

Here:

share_type — file storage type and pool segment in the format of <type>.<pool_segment>for example basic.ru-9a:
- <type>:
  - basic — HDD type Basic;
  - universal — SSD type Universal;
  - fast — SSD type Fast;
- <pool_segment> — the pool segment where the file storage will be created, e.g. ru-9a. The list of available pool segments can be found in the instructions Availability matrix;
share_proto — file storage protocol: NFS or CIFS;
size — file storage size in GB, e.g. 50. The limits are from 50 GB to 50 TB;
optional: metadata = {"ip": "<ip_address>"} — the private IP address of the file storage, e.g. 192.168.0.3. Once the storage is created, the IP address cannot be changed.

Check out the detailed description of the resource openstack_sharedfilesystem_share_v2.

5. Configure file storage access rules⁠

resource "openstack_sharedfilesystem_share_access_v2" "shareaccess_1" {
  access_level = "rw"
  access_to    = "0.0.0.0/0"
  access_type  = "ip"
  share_id     = openstack_sharedfilesystem_share_v2.share_1.id
}

Here:

access_level — access level to the vault depends on the protocol:
- for CIFS SMBv3 — rw (reading and writing);
- for NFSv4-- ro (read only) or rw (reading and writing);
access_to — The IP address or CIDR of the private subnet for which access will be granted. For example:
- 192.168.199.10 — access for an IP address;
- 192.168.199.0/24 — access for the private subnet range;
- 0.0.0.0/0 — access for all addresses on the private subnet. To configure this access, you can add to the resource openstack_sharedfilesystem_share_v2 string metadata = {"access_list_allow_all": "true"}.

Check out the detailed description of the resource openstack_sharedfilesystem_share_access_v2.

Create file storage

Configuration files⁠​

1. optional: configure providers⁠​

2. Create a private network and subnet⁠​

3. configure the storage network configuration⁠​

4. Create file storage⁠​

5. Configure file storage access rules⁠​

Configuration files⁠

1. optional: configure providers⁠

2. Create a private network and subnet⁠

3. configure the storage network configuration⁠

4. Create file storage⁠

5. Configure file storage access rules⁠