---
title: "Создать группу безопасности и назначить ее на порт облачного сервера через Terraform"
sidebar_label: "Создать группу безопасности и назначить ее на порт облачного сервера"
description: "Как создать группу безопасности с правилом и назначить ее на порт облачного сервера"
sidebar_position: 1
---

import ConfigureProviders from '@site/terraform/_partials/common/configure-providers.mdx'
import ConfigureProvidersConfig from '@site/terraform/_partials/common/configure-providers-config.mdx'
import CreatePort from '@site/terraform/_partials/cloud-servers/create-port.mdx'
import CreateResourcesAlert from '@site/terraform/_partials/common/create-resources-alert.mdx'
import CreateBootVolume from '@site/terraform/_partials/cloud-servers/create-boot-volume.mdx'
import AddPublicSsh from '@site/terraform/_partials/cloud-servers/add-public-ssh-key.mdx'
import CreateFixedServerBootNetwork from '@site/terraform/_partials/cloud-servers/create-fixed-server-with-boot-network-volume.mdx'
import GetImage from '@site/terraform/_partials/cloud-servers/get-image.mdx'
import CopyIcon from '@selectel/docux/icons/copy'
import Formbricks from '@theme/MDXComponents/Formbricks'

# Создать группу безопасности и назначить ее на порт облачного сервера через Terraform

<CreateResourcesAlert />

<br />

1. Опционально: [настройте провайдеры](#configure-providers).
2. [Создайте приватную сеть и подсеть](#create-networks).
3. [Создайте группу безопасности](#create-security-group).
4. [Создайте правило](#create-rule).
5. [Создайте порт в сети](#create-port).
6. [Назначьте группу на порт](#assign-security-group).
7. [Создайте сервер](#create-server).

## Конфигурационные файлы \{#config}

<details>
  <summary>Пример файла для настройки провайдеров</summary>

  <ConfigureProvidersConfig />
</details>

<details>
  <summary>Пример файла для создания группы безопасности и назначения группы на порт сервера</summary>

  ```hcl
  resource "openstack_networking_network_v2" "network_1" {
  name                  = "network"
  port_security_enabled = "true"
  }

  resource "openstack_networking_subnet_v2" "subnet_1" {
    name            = "subnet"
    network_id      = openstack_networking_network_v2.network_1.id
    cidr            = "192.168.0.0/24"
  }

  resource "openstack_networking_secgroup_v2" "security_group_1" {
    name        = "sg"
    description = "Test security group"
  }

  resource "openstack_networking_secgroup_rule_v2" "security_group_rule_1" {
    direction         = "ingress"
    ethertype         = "IPv4"
    protocol          = "tcp"
    port_range_min    = 443
    port_range_max    = 443
    remote_ip_prefix  = "0.0.0.0/0"
    security_group_id = openstack_networking_secgroup_v2.security_group_1.id
  }

  resource "openstack_networking_port_v2" "port_1" {
    name           = "port"
    network_id     = openstack_networking_network_v2.network_1.id
    admin_state_up = "true"

    fixed_ip {
      subnet_id  = openstack_networking_subnet_v2.subnet_1.id
    }
  }

  resource "openstack_networking_port_secgroup_associate_v2" "security_group_associate_1" {
    port_id            = openstack_networking_port_v2.port_1.id
    security_group_ids = [openstack_networking_secgroup_v2.security_group_1.id]
  }

  data "openstack_images_image_v2" "image_1" {
    name        = "Ubuntu 20.04 LTS 64-bit"
    most_recent = true
    visibility  = "public"
  }

  resource "selectel_vpc_keypair_v2" "keypair_1" {
    name       = "keypair"
    public_key = file("~/.ssh/id_rsa.pub")
    user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
  }

  resource "openstack_blockstorage_volume_v3" "volume_1" {
    name                 = "boot-volume"
    size                 = "5"
    image_id             = data.openstack_images_image_v2.image_1.id
    volume_type          = "fast.ru-9a"
    availability_zone    = "ru-9a"
    enable_online_resize = true

    lifecycle {
      ignore_changes = [image_id]
    }

  }

  resource "openstack_compute_instance_v2" "server_1" {
    name              = "server"
    flavor_id         = "4011"
    key_pair          = selectel_vpc_keypair_v2.keypair_1.name
    availability_zone = "ru-9a"

    network {
      port = openstack_networking_port_v2.port_1.id
    }

    lifecycle {
      ignore_changes = [image_id]
    }

    block_device {
      uuid             = openstack_blockstorage_volume_v3.volume_1.id
      source_type      = "volume"
      destination_type = "volume"
      boot_index       = 0
    }

    vendor_options {
      ignore_resize_confirmation = true
    }
  }

  ```
</details>

## 1. Опционально: настроить провайдеры \{#configure-providers}

Если вы [настроили провайдеры](/terraform/configure-terraform-environment/#configure-providers) Selectel и OpenStack, пропустите этот шаг.

<ConfigureProviders />

## 2. Создать приватную сеть и подсеть \{#create-networks}

```hcl
resource "openstack_networking_network_v2" "network_1" {
name                  = "network"
port_security_enabled = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name            = "subnet"
  network_id      = openstack_networking_network_v2.network_1.id
  cidr            = "192.168.0.0/24"
}
```

## 3. Создать группу безопасности \{#create-security-group}

```hcl
resource "openstack_networking_secgroup_v2" "security_group_1" {
  name        = "sg"
  description = "Test security group"
}
```

Посмотрите подробное описание ресурса [openstack\_networking\_secgroup\_v2](/terraform/openstack-provider-reference/networking-neutron/resources/openstack_networking_secgroup_v2/).

## 4. Создать правило \{#create-rule}

```hcl
resource "openstack_networking_secgroup_rule_v2" "security_group_rule_1" {
  direction         = "ingress"
  ethertype         = "IPv4"
  protocol          = "tcp"
  port_range_min    = 443
  port_range_max    = 443
  remote_ip_prefix  = "0.0.0.0/0"
  security_group_id = openstack_networking_secgroup_v2.security_group_1.id
}
```

Здесь:

* `direction` — направление трафика: `ingress` для входящего трафика, `egress` для исходящего;
* `ethertype` — тип протокола: `IPv4` или `IPv6`;
* `protocol` — протокол, например `tcp`;
* `port_range_min` — первый порт из диапазона портов, с которыми разрешено соединение, например `443`;
* `port_range_max` — последний порт из диапазона;
* `remote_ip_prefix` — IP-адреса, с которых разрешено принимать трафик, например `0.0.0.0/0`.

Посмотрите подробное описание ресурса [openstack\_networking\_secgroup\_rule\_v2](/terraform/openstack-provider-reference/networking-neutron/resources/openstack_networking_secgroup_rule_v2/).

## 5. Создать порт в сети \{#create-port}

<CreatePort />

## 6. Назначить группу на порт \{#assign-security-group}

```hcl
resource "openstack_networking_port_secgroup_associate_v2" "security_group_associate_1" {
    port_id            = openstack_networking_port_v2.port_1.id
    security_group_ids = [openstack_networking_secgroup_v2.security_group_1.id]
  }
```

Посмотрите подробное описание ресурса [openstack\_networking\_secgroup\_associate\_v2](/terraform/openstack-provider-reference/networking-neutron/resources/openstack_networking_port_secgroup_associate_v2/).

## 7. Создать облачный сервер \{#create-server}

### 1. Добавить публичный SSH-ключ \{#add-public-ssh-key}

<AddPublicSsh />

### 2. Получить образ⁠ \{#get-image}

<GetImage />

### 3. Создать загрузочный сетевой диск \{#create-boot-volume}

<CreateBootVolume />

### 4. Создать облачный сервер \{#create-server}

<CreateFixedServerBootNetwork />

<Formbricks />