---
title: "Создать кластер Kafka через Terraform"
sidebar_label: "Создать кластер Kafka"
description: "Как создать кластер Kafka с базой данных"
sidebar_position: 6
---

import Formbricks from '@theme/MDXComponents/Formbricks'
import ConfigureProviders from '@site/terraform/_partials/common/configure-providers.mdx'
import ConfigureProvidersConfig from '@site/terraform/_partials/common/configure-providers-config.mdx'
import CreateResourcesAlert from '@site/terraform/_partials/common/create-resources-alert.mdx'
import CreateNetworks from '@site/terraform/_partials/cloud-networks/create-networks.mdx'
import Tabs from '@theme/Tabs'
import TabItem from '@theme/TabItem'
import {TabItemLabel} from '@selectel/docux/components'

# Создать кластер Kafka через Terraform

<CreateResourcesAlert />

<br />

1. Опционально: [настройте провайдеры](#configure-providers).
2. [Создайте приватную сеть и подсеть](#create-networks).
3. [Создайте кластер](#create-cluster).
4. [Создайте пользователя](#create-user).
5. [Создайте топик](#create-topic).
6. [Выдайте доступ пользователю](#grant-access).

## Конфигурационные файлы \{#config}

<details>
  <summary>Пример файла для настройки провайдеров</summary>

  <ConfigureProvidersConfig />
</details>

<details>
  <summary>Пример файла для создания кластера Kafka фиксированной конфигурации</summary>

  ```hcl
  resource "openstack_networking_network_v2" "network_1" {
    name           = "private-network"
    admin_state_up = "true"
  }

  resource "openstack_networking_subnet_v2" "subnet_1" {
    network_id = openstack_networking_network_v2.network_1.id
    cidr       = "192.168.199.0/24"
  }

  data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
    project_id = selectel_vpc_project_v2.project_1.id
    region     = "ru-9"
    filter {
      engine  = "kafka"
      version = "3.5"
    }
  }

  data "selectel_dbaas_flavor_v1" "flavor_1" {
    project_id = selectel_vpc_project_v2.project_1.id
    region     = "ru-9"
    filter {
      datastore_type_id = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
      fl_size           = "standard"
      vcpus             = 4
      ram               = 16384
      disk              = 128
    }
  }

  resource "selectel_dbaas_kafka_datastore_v1" "datastore_1" {
    name       = "datastore-1"
    project_id = selectel_vpc_project_v2.project_1.id
    region     = "ru-9"
    type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
    subnet_id  = openstack_networking_subnet_v2.subnet_1.id
    node_count = 1
    flavor_id  = data.selectel_dbaas_flavor_v1.flavor_1.flavors[0].id
  }

  resource "selectel_dbaas_user_v1" "user_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_kafka_datastore_v1.datastore_1.id
    name         = "user"
    password     = "secret"
  }

  resource "selectel_dbaas_kafka_topic_v1" "topic_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_kafka_datastore_v1.datastore_1.id
    name         = "topic"
    partitions   = 1
  }

  resource "selectel_dbaas_kafka_acl_v1" "acl_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_kafka_datastore_v1.datastore_1.id
    pattern      = "topic"
    pattern_type = "prefixed"
    allow_read   = true
    allow_write  = true
    user_id      = selectel_dbaas_user_v1.user_1.id
  }
  ```
</details>

<details>
  <summary>Пример файла для создания кластера Kafka произвольной конфигурации</summary>

  ```hcl
  resource "openstack_networking_network_v2" "network_1" {
    name           = "private-network"
    admin_state_up = "true"
  }

  resource "openstack_networking_subnet_v2" "subnet_1" {
    network_id = openstack_networking_network_v2.network_1.id
    cidr       = "192.168.199.0/24"
  }

  data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
    project_id = selectel_vpc_project_v2.project_1.id
    region     = "ru-9"
    filter {
      engine  = "kafka"
      version = "3.5"
    }
  }

  resource "selectel_dbaas_kafka_datastore_v1" "datastore_1" {
    name       = "datastore-1"
    project_id = selectel_vpc_project_v2.project_1.id
    region     = "ru-9"
    type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
    subnet_id  = selectel_vpc_subnet_v2.subnet.subnet_id
    node_count = 1
    flavor {
      vcpus = 2
      ram   = 8192
      disk  = 64
    }
  }

  resource "selectel_dbaas_user_v1" "user_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_kafka_datastore_v1.datastore_1.id
    name         = "user"
    password     = "secret"
  }

  resource "selectel_dbaas_kafka_topic_v1" "topic_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_kafka_datastore_v1.datastore_1.id
    name         = "topic"
    partitions   = 1
  }

  resource "selectel_dbaas_kafka_acl_v1" "acl_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_kafka_datastore_v1.datastore_1.id
    pattern      = "topic"
    pattern_type = "prefixed"
    allow_read   = true
    allow_write  = true
    user_id      = selectel_dbaas_user_v1.user_1.id
  }
  ```
</details>

## 1. Опционально: настроить провайдеры \{#configure-providers}

Если вы [настроили провайдеры](/terraform/configure-terraform-environment/#configure-providers) Selectel и OpenStack, пропустите этот шаг.

<ConfigureProviders />

## 2. Создать приватную сеть и подсеть \{#create-networks}

<CreateNetworks />

## 3. Создать кластер \{#create-cluster}

<Tabs queryString="create-cluster">
  <TabItem value="fixed" default>
    <TabItemLabel>
      Фиксированная конфигурация
    </TabItemLabel>

    ```hcl
    data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      filter {
        engine  = "kafka"
        version = "3.5"
      }
    }

    data "selectel_dbaas_flavor_v1" "flavor_1" {
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      filter {
        datastore_type_id = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
        fl_size           = "standard"
        vcpus             = 4
        ram               = 16384
        disk              = 128
      }
    }

    resource "selectel_dbaas_kafka_datastore_v1" "datastore_1" {
      name       = "datastore-1"
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
      subnet_id  = openstack_networking_subnet_v2.subnet_1.id
      node_count = 1
      flavor_id  = data.selectel_dbaas_flavor_v1.flavor_1.flavors[0].id
    }
    ```

    Здесь:

    * `region` — пул, например `ru-9`. Список доступных пулов можно посмотреть в инструкции [Доступность продуктов в локациях](/infrastructure/product-availability-by-location/#managed-databases);
    * `filter` — фильтр типов облачных баз данных:
      * `engine` — тип облачных баз данных;
      * `version` — версия облачной базы данных. Список доступных версий можно посмотреть в инструкции [Версии и конфигурации](/managed-databases/kafka/configurations/);
    * `nodes_count` — количество нод. Максимальное количество нод — 1;
    * `filter` — фильтр фиксированных конфигураций кластера. Список доступных конфигураций можно посмотреть в инструкции [Версии и конфигурации](/managed-databases/kafka/configurations/);
      * `fl_size` — [линейка фиксированных конфигураций](/managed-databases/kafka/configurations/). Доступные значения — `standard` (для линеек Standard, CPU и Memory) и `high_freq` (для линейки HighFreq);
      * `vcpus` — количество vCPU;
      * `ram` — количество RAM в МБ;
      * `disk` — размер диска в ГБ.

    Посмотрите подробное описание источников данных и ресурсов:

    * [selectel\_dbaas\_datastore\_type\_v1](/terraform/selectel-provider-reference/data-sources/dbaas_datastore_type_v1/);
    * [selectel\_dbaas\_flavor\_v1](/terraform/selectel-provider-reference/data-sources/dbaas_flavor_v1/);
    * [selectel\_dbaas\_kafka\_datastore\_v1](/terraform/selectel-provider-reference/resources/dbaas_kafka_datastore_v1/).
  </TabItem>

  <TabItem value="custom">
    <TabItemLabel>
      Произвольная конфигурация
    </TabItemLabel>

    ```hcl
    data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      filter {
        engine  = "kafka"
        version = "3.5"
      }
    }

    resource "selectel_dbaas_kafka_datastore_v1" "datastore_1" {
      name       = "datastore-1"
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
      subnet_id  = openstack_networking_subnet_v2.subnet_1.id
      node_count = 1
      flavor {
        vcpus = 2
        ram   = 8192
        disk  = 64
      }
    }
    ```

    Здесь:

    * `region` — пул, например `ru-9`. Список доступных пулов можно посмотреть в инструкции [Доступность продуктов в локациях](/infrastructure/product-availability-by-location/#managed-databases);
    * `filter` — фильтр типов облачных баз данных:
      * `engine` — тип облачных баз данных;
      * `version` — версия облачной базы данных. Список доступных версий можно посмотреть в инструкции [Версии и конфигурации](/managed-databases/kafka/configurations/);
    * `node_count` — количество нод. Максимальное количество нод — 1;
    * `flavor` — произвольная конфигурация кластера. Доступные значения произвольных конфигураций можно посмотреть в инструкции [Версии и конфигурации](/managed-databases/kafka/configurations/):
      * `vcpus` — количество vCPU;
      * `ram` — количество RAM в МБ;
      * `disk` — размер диска в ГБ.

    Посмотрите подробное описание источника данных [selectel\_dbaas\_datastore\_type\_v1](/terraform/selectel-provider-reference/data-sources/dbaas_datastore_type_v1/) и ресурса [selectel\_dbaas\_kafka\_datastore\_v1](/terraform/selectel-provider-reference/resources/dbaas_kafka_datastore_v1/).
  </TabItem>
</Tabs>

## 4. Создать пользователя \{#create-user}

```hcl
resource "selectel_dbaas_user_v1" "user_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_kafka_datastore_v1.datastore_1.id
  name         = "user"
  password     = "secret"
}
```

Здесь:

* `region` — пул, в котором находится кластер;
* `name` — имя пользователя;
* `password` — пароль пользователя.

Посмотрите подробное описание ресурса [selectel\_dbaas\_user\_v1](/terraform/selectel-provider-reference/resources/dbaas_user_v1/).

## 5. Создать топик \{#create-topic}

```hcl
resource "selectel_dbaas_kafka_topic_v1" "topic_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_kafka_datastore_v1.datastore_1.id
  name         = "topic"
  partitions   = 1
}
```

Здесь:

* `region` — пул, в котором находится кластер;
* `partitions` — количество разделов в топике.

Посмотрите подробное описание ресурса [selectel\_dbaas\_kafka\_topic\_v1](/terraform/selectel-provider-reference/resources/dbaas_kafka_topic_v1/).

## 6. Выдать доступ пользователю \{#grant-access}

```hcl
resource "selectel_dbaas_kafka_acl_v1" "acl_1" {
  project_id   = selectel_vpc_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = selectel_dbaas_kafka_datastore_v1.datastore_1.id
  pattern      = "topic"
  pattern_type = "prefixed"
  allow_read   = true
  allow_write  = true
  user_id      = selectel_dbaas_user_v1.user_1.id
}
```

Здесь:

* `region` — пул, в котором находится кластер;
* `pattern` — имя или префикс топика, к которому предоставлен доступ. Пропустите аргумент, если `pattern_type = all`;
* `pattern_type` — тип доступа к топикам. Доступные значения — `prefixed`, `literal`, `all`. Если `pattern_type = all`, пропустите аргумент `pattern`;
* `allow_read` — предоставляет пользователю роль консьюмера. Пользователь получает и обрабатывает сообщения из топика, к которому он имеет доступ;
* `allow_write` — предоставляет пользователю роль продюсера. Пользователь отправляет сообщения в топик, к которому он имеет доступ.

Посмотрите подробное описание ресурса [selectel\_dbaas\_kafka\_acl\_v1](/terraform/selectel-provider-reference/resources/dbaas_kafka_acl_v1/).

<Formbricks />