Создать файловое хранилище

Последнее изменение: 11 ноября 2024

Создать файловое хранилище

Мы рекомендуем создавать ресурсы по порядку. Если вы единовременно создаете все ресурсы, которые описаны в конфигурационном файле, может возникнуть ошибка — Terraform создает ресурсы независимо от порядка, в котором они перечислены в файле.

1. Опционально: настройте провайдеры.
2. Создайте приватную сеть и подсеть.
3. Настройте конфигурацию сети хранилища.
4. Создайте файловое хранилище.
5. Настройте правила доступа к файловому хранилищу.

Конфигурационные файлы⁠

Пример файла для настройки провайдеров

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "6.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Пример файла для создания файлового хранилища

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

resource "openstack_sharedfilesystem_sharenetwork_v2" "sharenetwork_1" {
  name              = "share-network"
  neutron_net_id    = openstack_networking_network_v2.network_1.id
  neutron_subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

resource "openstack_sharedfilesystem_share_v2" "share_1" {
  name             = "nfs-storage"
  share_type       = "basic.ru-9a"
  share_proto      = "NFS"
  size             = 50
  share_network_id = openstack_sharedfilesystem_sharenetwork_v2.sharenetwork_1.id
  metadata         = {"ip": "192.168.199.3"}
}

resource "openstack_sharedfilesystem_share_access_v2" "shareaccess_1" {
  access_level = "rw"
  access_to    = "0.0.0.0/0"
  access_type  = "ip"
  share_id     = openstack_sharedfilesystem_share_v2.share_1.id
}

1. Опционально: настроить провайдеры⁠

Если вы настроили провайдеры Selectel и OpenStack, пропустите этот шаг.

1. Убедитесь, что в панели управления вы создали сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей.

2. Создайте директорию для хранения конфигурационных файлов и отдельный файл с расширением .tf для настройки провайдеров.

3. В файл для настройки провайдеров добавьте провайдеры Selectel и OpenStack:

   terraform {
     required_providers {
       selectel  = {
         source  = "selectel/selectel"
         version = "6.0.0"
       }
       openstack = {
         source  = "terraform-provider-openstack/openstack"
         version = "2.1.0"
       }
     }
   }

   Здесь version — версии провайдеров. Актуальную версию можно посмотреть в документации Selectel (в Terraform Registry и GitHub) и OpenStack (в Terraform Registry и GitHub).

   Подробнее о продуктах, услугах и сервисах, которыми можно управлять с помощью провайдеров, в инструкции Провайдеры Selectel и OpenStack.

4. Инициализируйте провайдер Selectel:

   provider "selectel" {
     domain_name = "123456"
     username    = "user"
     password    = "password"
   }

   Здесь:

   • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
   • username — имя сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей. Можно посмотреть в панели управления: раздел Управление доступом → Управление пользователями → вкладка Сервисные пользователи (раздел доступен только Владельцу аккаунта и Администратору пользователей);
   • password — пароль сервисного пользователя. Можно посмотреть при создании пользователя или изменить на новый.

5. Создайте проект:

   resource "selectel_vpc_project_v2" "project_1" {
     name = "project"
   }

   Посмотрите подробное описание ресурса selectel_vpc_project_v2.

6. Создайте сервисного пользователя для доступа к проекту и назначьте ему роль Администратор проекта:

   resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
     name         = "username"
     password     = "password"
     role {
       role_name  = "member"
       scope      = "project"
       project_id = selectel_vpc_project_v2.project_1.id 
     }
   }

   Здесь:

   • username — имя пользователя;
   • password — пароль пользователя. Пароль должен быть не короче восьми символов и содержать латинские буквы разных регистров и цифры;
   • project_id — ID проекта. Можно посмотреть в панели управления: раздел Облачная платформа → откройте меню проектов (название текущего проекта) → в строке нужного проекта нажмите .

   Посмотрите подробное описание ресурса selectel_iam_serviceuser_v1.

7. Инициализируйте провайдер OpenStack:

   provider "openstack" {
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
     domain_name = "123456"
     tenant_id   = selectel_vpc_project_v2.project_1.id
     user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
     password    = selectel_iam_serviceuser_v1.serviceuser_1.password
     region      = "ru-9"
   }

   Здесь:

   • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
   • region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

8. Если одновременно с настройкой провайдеров вы создаете ресурсы, то для ресурсов OpenStack добавьте аргумент depends_on. Например, для ресурса openstack_networking_network_v2:

   resource "openstack_networking_network_v2" "network_1" {
     name           = "private-network"
     admin_state_up = "true"
   
     depends_on = [
       selectel_vpc_project_v2.project_1,
       selectel_iam_serviceuser_v1.serviceuser_1
     ]
   }

9. Опционально: если вы хотите использовать зеркало, создайте отдельный конфигурационный файл Terraform CLI и добавьте в него блок:

   provider_installation {
     network_mirror {
       url = "https://tf-proxy.selectel.ru/mirror/v1/"
       include = ["registry.terraform.io/*/*"]
     }
     direct {
       exclude = ["registry.terraform.io/*/*"]
     }
   }

   Подробнее о настройках зеркал в инструкции CLI Configuration File документации HashiCorp.

10. Откройте CLI.

11. Инициализируйте конфигурацию Terraform в директории:

    terraform init

12. Проверьте, что конфигурационные файлы составлены без ошибок:

    terraform validate

13. Отформатируйте конфигурационные файлы:

    terraform fmt

14. Проверьте, какие ресурсы будут созданы:

    terraform plan

15. Примените изменения и создайте ресурсы:

    terraform apply

16. Подтвердите создание — введите yes и нажмите Enter. Созданные ресурсы отобразятся в панели управления.

17. Если для создания ресурсов оказалось недостаточно квот, увеличьте квоты.

2. Создать приватную сеть и подсеть⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Здесь cidr — CIDR приватной подсети, например 192.168.199.0/24.

Посмотрите подробное описание ресурсов:

• openstack_networking_network_v2;
• openstack_networking_subnet_v2.

3. Настроить конфигурацию сети хранилища⁠

resource "openstack_sharedfilesystem_sharenetwork_v2" "sharenetwork_1" {
  name              = "share-network"
  neutron_net_id    = openstack_networking_network_v2.network_1.id
  neutron_subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

Посмотрите подробное описание ресурса openstack_sharedfilesystem_sharenetwork_v2.

4. Создать файловое хранилище⁠

resource "openstack_sharedfilesystem_share_v2" "share_1" {
  name             = "nfs-storage"
  share_type       = "basic.ru-9a"
  share_proto      = "NFS"
  size             = 50
  share_network_id = openstack_sharedfilesystem_sharenetwork_v2.sharenetwork_1.id
  metadata         = {"ip": "192.168.199.3"}
}

Здесь:

• share_type — тип файлового хранилища и сегмент пула в формате <type>.<pool_segment>, например basic.ru-9a:
  • <type>:
    • basic — тип HDD Базовое;
    • universal — тип SSD Универсальное;
    • fast — тип SSD Быстрое;
  • <pool_segment> — сегмент пула, в котором будет создано файловое хранилище, например ru-9a. Список доступных сегментов пула можно посмотреть в инструкции Матрицы доступности;
• share_proto — протокол файлового хранилища: NFS или CIFS;
• size — размер файлового хранилища в ГБ, например 50. Ограничения — от 50 ГБ до 50 ТБ;
• опционально: metadata = {"ip": "<ip_address>"} — приватный IP-адрес файлового хранилища, например 192.168.0.3. После создания хранилища IP-адрес нельзя будет изменить.

Посмотрите подробное описание ресурса openstack_sharedfilesystem_share_v2.

5. Настроить правила доступа к файловому хранилищу⁠

resource "openstack_sharedfilesystem_share_access_v2" "shareaccess_1" {
  access_level = "rw"
  access_to    = "0.0.0.0/0"
  access_type  = "ip"
  share_id     = openstack_sharedfilesystem_share_v2.share_1.id
}

Здесь:

• access_level — уровень доступа к хранилищу, зависит от протокола:
  • для CIFS SMBv3 — rw (чтение и запись);
  • для NFSv4 — ro (только чтение) или rw (чтение и запись);
• access_to — IP-адрес или CIDR приватной подсети, для которых будет открыт доступ. Например:
  • 192.168.199.10 — доступ для IP-адреса;
  • 192.168.199.0/24 — доступ для диапазона приватной подсети;
  • 0.0.0.0/0 — доступ для всех адресов приватной подсети. Для настройки этого доступа можно добавить в ресурс openstack_sharedfilesystem_share_v2 строку metadata = {"access_list_allow_all": "true"}.

Посмотрите подробное описание ресурса openstack_sharedfilesystem_share_access_v2.