Перейти к основному содержимому
Создать несколько одинаковых облачных серверов в одной приватной сети
Последнее изменение:

Создать несколько одинаковых облачных серверов в одной приватной сети

Мы рекомендуем создавать ресурсы по порядку. Если вы единовременно создаете все ресурсы, которые описаны в конфигурационном файле, может возникнуть ошибка — Terraform создает ресурсы независимо от порядка, в котором они перечислены в файле.


  1. Опционально: настройте провайдеры.

  2. Создайте пару SSH-ключей.

  3. Создайте приватную сеть и подсеть.

  4. Создайте облачный роутер, подключенный к внешней сети.

  5. Создайте порты для облачных серверов.

  6. Получите образ.

  7. Создайте облачные серверы.

  8. Создайте публичные IP-адреса.

  9. Ассоциировать публичные и приватные IP-адреса облачных серверов.

Конфигурационные файлы⁠

Пример файла для настройки провайдеров
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~>6.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}
Пример файла для создания серверов
    resource "selectel_vpc_keypair_v2" "keypair_1" {
        name       = "keypair"
        public_key = file("~/.ssh/id_rsa.pub")
        user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
    }

    resource "openstack_networking_network_v2" "network_1" {
        name           = "private-network"
        admin_state_up = "true"
    }

    resource "openstack_networking_subnet_v2" "subnet_1" {
        network_id = openstack_networking_network_v2.network_1.id
        cidr       = "192.168.199.0/24"
    }

    data "openstack_networking_network_v2" "external_network_1" {
        external = true
    }

    resource "openstack_networking_router_v2" "router_1" {
        name                = "router"
        external_network_id = data.openstack_networking_network_v2.external_network_1.id
    }

    resource "openstack_networking_router_interface_v2" "router_interface_1" {
        router_id = openstack_networking_router_v2.router_1.id
        subnet_id = openstack_networking_subnet_v2.subnet_1.id
    }

    resource "openstack_networking_port_v2" "port" {
        name       = "port"
        count      = 3
        network_id = openstack_networking_network_v2.network2.id

        fixed_ip {
            subnet_id = openstack_networking_subnet_v2.subnet_2.id
        }

    }

    data "openstack_images_image_v2" "image_1" {
        name        = "Ubuntu 20.04 LTS 64-bit"
        most_recent = true
        visibility  = "public"
    }

    resource "openstack_compute_instance_v2" "instance_test" {
        name              = "server"
        count             = 3
        image_id          = data.openstack_images_image_v2.ubuntu.id
        flavor_id         = "1312"
        key_pair          = selectel_vpc_keypair_v2.keypair_1.name
        availability_zone = "ru-9a"

        network {
            port = openstack_networking_port_v2.port[count.index].id
        }

        lifecycle {
            ignore_changes = [image_id]
        }

        vendor_options {
            ignore_resize_confirmation = true
        }

    }

    resource "openstack_networking_floatingip_v2" "floatingip" {
        pool  = "external-network"
        count = 3
    }

    resource "openstack_networking_floatingip_associate_v2" "association" {
        count       = 3
        port_id     = openstack_networking_port_v2.port[count.index].id
        floating_ip = openstack_networking_floatingip_v2.floatingip[count.index].address
    }

1. Опционально: настроить провайдеры⁠

Если вы настроили провайдеры Selectel и OpenStack, пропустите этот шаг.

  1. Убедитесь, что в панели управления вы создали сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей.

  2. Создайте директорию для хранения конфигурационных файлов и отдельный файл с расширением .tf для настройки провайдеров.

  3. В файл для настройки провайдеров добавьте провайдеры Selectel и OpenStack:

    terraform {
      required_providers {
        selectel  = {
          source  = "selectel/selectel"
          version = "6.0.0"
        }
        openstack = {
          source  = "terraform-provider-openstack/openstack"
          version = "2.1.0"
        }
      }
    }

    Здесь version — версии провайдеров. Актуальную версию можно посмотреть в документации Selectel (в Terraform Registry и GitHub) и OpenStack (в Terraform Registry и GitHub).

    Подробнее о продуктах, услугах и сервисах, которыми можно управлять с помощью провайдеров, в инструкции Провайдеры Selectel и OpenStack.

  4. Инициализируйте провайдер Selectel:

    provider "selectel" {
      domain_name = "123456"
      username    = "user"
      password    = "password"
      auth_region = "ru-9"
      auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
    }

    Здесь:

    • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
    • username — имя сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей. Можно посмотреть в панели управления: раздел Управление доступом → Управление пользователями → вкладка Сервисные пользователи (раздел доступен только Владельцу аккаунта и Администратору пользователей);
    • password — пароль сервисного пользователя. Можно посмотреть при создании пользователя или изменить на новый;
    • auth_region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

  5. Создайте проект:

    resource "selectel_vpc_project_v2" "project_1" {
      name = "project"
    }

    Посмотрите подробное описание ресурса selectel_vpc_project_v2.

  6. Создайте сервисного пользователя для доступа к проекту и назначьте ему роль Администратор проекта:

    resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
      name         = "username"
      password     = "password"
      role {
        role_name  = "member"
        scope      = "project"
        project_id = selectel_vpc_project_v2.project_1.id 
      }
    }

    Здесь:

    • username — имя пользователя;
    • password — пароль пользователя. Пароль должен быть не короче восьми символов и содержать латинские буквы разных регистров и цифры;
    • project_id — ID проекта. Можно посмотреть в панели управления: раздел Облачная платформа → откройте меню проектов (название текущего проекта) → в строке нужного проекта нажмите .

    Посмотрите подробное описание ресурса selectel_iam_serviceuser_v1.

  7. Инициализируйте провайдер OpenStack:

    provider "openstack" {
      auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
      domain_name = "123456"
      tenant_id   = selectel_vpc_project_v2.project_1.id
      user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
      password    = selectel_iam_serviceuser_v1.serviceuser_1.password
      region      = "ru-9"
    }

    Здесь:

    • domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
    • region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

  8. Если одновременно с настройкой провайдеров вы создаете ресурсы, то для ресурсов OpenStack добавьте аргумент depends_on. Например, для ресурса openstack_networking_network_v2:

    resource "openstack_networking_network_v2" "network_1" {
      name           = "private-network"
      admin_state_up = "true"

      depends_on = [
        selectel_vpc_project_v2.project_1,
        selectel_iam_serviceuser_v1.serviceuser_1
      ]
    }

  9. Опционально: если вы хотите использовать зеркало, создайте отдельный конфигурационный файл Terraform CLI и добавьте в него блок:

    provider_installation {
      network_mirror {
        url = "https://tf-proxy.selectel.ru/mirror/v1/"
        include = ["registry.terraform.io/*/*"]
      }
      direct {
        exclude = ["registry.terraform.io/*/*"]
      }
    }

    Подробнее о настройках зеркал в инструкции CLI Configuration File документации HashiCorp.

  10. Откройте CLI.

  11. Инициализируйте конфигурацию Terraform в директории:

    terraform init

  12. Проверьте, что конфигурационные файлы составлены без ошибок:

    terraform validate

  13. Отформатируйте конфигурационные файлы:

    terraform fmt

  14. Проверьте, какие ресурсы будут созданы:

    terraform plan

  15. Примените изменения и создайте ресурсы:

    terraform apply

  16. Подтвердите создание — введите yes и нажмите Enter. Созданные ресурсы отобразятся в панели управления.

  17. Если для создания ресурсов оказалось недостаточно квот, увеличьте квоты.

2. Создать пару SSH-ключей⁠

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

Здесь public_key — путь до публичного SSH-ключа. Если SSH-ключи не созданы, сгенерируйте их.

Посмотрите подробное описание ресурса selectel_vpc_keypair_v2.

3. Создать приватную сеть и подсеть⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Здесь cidr — CIDR приватной подсети, например 192.168.199.0/24.

Посмотрите подробное описание ресурсов:

4. Создать облачный роутер, подключенный к внешней сети⁠

Облачный роутер, подключенный к внешней сети, выполняет функцию 1:1 NAT для доступа из приватной сети в интернет через публичный IP-адрес роутера.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

Посмотрите подробное описание ресурсов:

5. Создать порты для облачных серверов⁠

resource "openstack_networking_port_v2" "port" {
  name       = "port"
  count      = 3
  network_id = openstack_networking_network_v2.network2.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_2.id
  }
}

Здесь count — количество портов.

Посмотрите подробное описание ресурса openstack_networking_port_v2.

6. Получить образ⁠

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

Посмотрите подробное описание источника данных openstack_images_image_v2.

7. Создать облачные серверы⁠

resource "openstack_compute_instance_v2" "instance_test" {
  name              = "server"
  count             = 3
  image_id          = data.openstack_images_image_v2.ubuntu.id
  flavor_id         = "1312"
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port[count.index].id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Здесь:

  • count — количество серверов;
  • flavor_id — ID флейвора. Например, 1312 — ID флейвора с фиксированной конфигурацией линейки Standard Line c 1 vCPU, 2048 ГБ RAM, 16 ГБ локального диска. Список флейворов можно посмотреть с помощью команды openstack flavor list или в таблице Список флейворов фиксированной конфигурации во всех пулах;
  • availability_zone — сегмент пула, в котором будут созданы облачные серверы, например ru-9a. Список доступных сегментов пула можно посмотреть в инструкции Матрицы доступности.

Посмотрите подробное описание ресурса openstack_compute_instance_v2.

8. Создать публичные IP-адреса⁠

resource "openstack_networking_floatingip_v2" "floatingip" {
  count = 3  
  pool  = "external-network"
}

Здесь count — количество публичных IP-адресов.

Посмотрите подробное описание ресурса openstack_networking_floatingip_v2.

9. Ассоциировать публичные и приватные IP-адреса облачных серверов⁠

Публичные IP-адреса будут подключены к портам облачных серверов и ассоциированы с приватными IP-адресами.

resource "openstack_networking_floatingip_associate_v2" "association" {
  count       = 3
  port_id     = openstack_networking_port_v2.port[count.index].id
  floating_ip = openstack_networking_floatingip_v2.floatingip[count.index].address
}

Здесь count — количество ассоциаций публичных и приватных IP-адресов.

Посмотрите подробное описание ресурса openstack_networking_floatingip_associate_v2.