---
title: "Создать облачный сервер в публичной подсети через Terraform"
sidebar_label: "Создать облачный сервер в публичной подсети"
sidebar_position: 2
description: "Как создать облачный сервер в публичной подсети"
---

import Formbricks from '@theme/MDXComponents/Formbricks'
import ConfigureProviders from '@site/terraform/_partials/common/configure-providers.mdx'
import ConfigureProvidersConfig from '@site/terraform/_partials/common/configure-providers-config.mdx'
import AddPublicSsh from '@site/terraform/_partials/cloud-servers/add-public-ssh-key.mdx'
import GetImage from '@site/terraform/_partials/cloud-servers/get-image.mdx'
import CreateBootVolume from '@site/terraform/_partials/cloud-servers/create-boot-volume.mdx'
import CreatePublicSubnet from '@site/terraform/_partials/cloud-networks/create-public-subnet.mdx'
import CreateFixedServerBootNetwork from '@site/terraform/_partials/cloud-servers/create-fixed-server-with-boot-network-volume.mdx'
import CreateResourcesAlert from '@site/terraform/_partials/common/create-resources-alert.mdx'

# Создать облачный сервер в публичной подсети через Terraform

<CreateResourcesAlert />

<br />

1. Опционально: [настройте провайдеры](#configure-providers).
2. [Добавьте публичный SSH-ключ](#add-public-ssh-key).
3. [Создайте публичную подсеть](#create-public-subnet).
4. [Создайте порт для облачного сервера](#create-port).
5. [Получите образ](#get-image).
6. [Создайте загрузочный сетевой диск](#create-boot-volume).
7. [Создайте облачный сервер](#create-server).
8. [Получитe IP-адрес облачного сервера](#get-ip).

## Конфигурационные файлы \{#config}

<details>
  <summary>Пример файла для настройки провайдеров</summary>

  <ConfigureProvidersConfig />
</details>

<details>
  <summary>Пример файла для создания облачного сервера в публичной подсети</summary>

  ```hcl
  resource "selectel_vpc_keypair_v2" "keypair_1" {
    name       = "keypair"
    public_key = file("~/.ssh/id_rsa.pub")
    user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
  }

  resource "selectel_vpc_subnet_v2" "subnet_1" {
    project_id    = selectel_vpc_project_v2.project_1.id
    region        = "ru-9"
    ip_version    = "ipv4"
    prefix_length = 29
  }

  resource "openstack_networking_port_v2" "port_1" {
    name       = "port"
    network_id = selectel_vpc_subnet_v2.subnet_1.network_id

    fixed_ip {
      subnet_id = selectel_vpc_subnet_v2.subnet_1.subnet_id
    }
  }

  data "openstack_images_image_v2" "image_1" {
    name        = "Ubuntu 20.04 LTS 64-bit"
    most_recent = true
    visibility  = "public"
  }

  resource "openstack_blockstorage_volume_v3" "volume_1" {
    name                 = "boot-volume-for-server"
    size                 = "5"
    image_id             = data.openstack_images_image_v2.image_1.id
    volume_type          = "fast.ru-9a"
    availability_zone    = "ru-9a"
    enable_online_resize = true

    lifecycle {
      ignore_changes = [image_id]
    }

  }

  resource "openstack_compute_instance_v2" "server_1" {
    name              = "server"
    flavor_id         = "4011"
    key_pair          = selectel_vpc_keypair_v2.keypair_1.name
    availability_zone = "ru-9a"

    network {
      port = openstack_networking_port_v2.port_1.id
    }

    lifecycle {
      ignore_changes = [image_id]
    }

    block_device {
      uuid             = openstack_blockstorage_volume_v3.volume_1.id
      source_type      = "volume"
      destination_type = "volume"
      boot_index       = 0
    }

    vendor_options {
      ignore_resize_confirmation = true
    }
  }

  output "public_ip_address" {
    value = openstack_compute_instance_v2.server_1.access_ip_v4
  }
  ```
</details>

## 1. Опционально: настроить провайдеры \{#configure-providers}

Если вы [настроили провайдеры](/terraform/configure-terraform-environment/#configure-providers) Selectel и OpenStack, пропустите этот шаг.

<ConfigureProviders />

## 2. Добавить публичный SSH-ключ \{#add-public-ssh-key}

<AddPublicSsh />

## 3. Создать публичную подсеть \{#create-public-subnet}

<CreatePublicSubnet />

## 4. Создать порт для облачного сервера \{#create-port}

```hcl
resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = selectel_vpc_subnet_v2.subnet_1.network_id

  fixed_ip {
    subnet_id = selectel_vpc_subnet_v2.subnet_1.subnet_id
  }
}
```

Посмотрите подробное описание ресурса [openstack\_networking\_port\_v2](/terraform/openstack-provider-reference/networking-neutron/resources/openstack_networking_port_v2/).

## 5. Получить образ \{#get-image}

<GetImage />

## 6. Создать загрузочный сетевой диск \{#create-boot-volume}

<CreateBootVolume />

## 7. Создать облачный сервер \{#create-server}

<CreateFixedServerBootNetwork />

## 8. Получить IP-адрес облачного сервера \{#get-ip}

```hcl
output "public_ip_address" {
  value = openstack_compute_instance_v2.server_1.access_ip_v4
}
```

<Formbricks />