---
title: "Создать облачный сервер с прямым публичным IP-адресом через Terraform"
sidebar_label: "Создать облачный сервер с прямым публичным IP-адресом"
sidebar_position: 4
description: "Как создать облачный сервер с прямым публичным IP-адресом"
---

import Formbricks from '@theme/MDXComponents/Formbricks'
import ConfigureProviders from '@site/terraform/_partials/common/configure-providers.mdx'
import ConfigureProvidersConfig from '@site/terraform/_partials/common/configure-providers-config.mdx'
import AddPublicSsh from '@site/terraform/_partials/cloud-servers/add-public-ssh-key.mdx'
import GetImage from '@site/terraform/_partials/cloud-servers/get-image.mdx'
import CreateBootVolume from '@site/terraform/_partials/cloud-servers/create-boot-volume.mdx'
import CreateFixedServerBootNetwork from '@site/terraform/_partials/cloud-servers/create-fixed-server-with-boot-network-volume.mdx'
import CreateResourcesAlert from '@site/terraform/_partials/common/create-resources-alert.mdx'
import GetIp from '@site/terraform/_partials/cloud-networks/get-ip.mdx'

# Создать облачный сервер с прямым публичным IP-адресом через Terraform

<CreateResourcesAlert />

<br />

1. Опционально: [настройте провайдеры](#configure-providers).
2. [Добавьте публичный SSH-ключ](#add-public-ssh-key).
3. [Создайте группу безопасности](#create-security-group).
4. [Создайте порт с прямым публичным IP-адресом](#create-port).
5. [Получите образ](#get-image).
6. [Создайте загрузочный сетевой диск](#create-boot-volume).
7. [Создайте облачный сервер](#create-server).
8. [Получите IP-адрес облачного сервера](#get-ip).

## Конфигурационные файлы \{#config}

<details>
  <summary>Пример файла для настройки провайдеров</summary>

  <ConfigureProvidersConfig />
</details>

<details>
  <summary>Пример файла для создания облачного сервера с прямым публичным IP-адресом</summary>

  ```hcl
  resource "selectel_vpc_keypair_v2" "keypair_1" {
    name       = "keypair"
    public_key = file("~/.ssh/id_rsa.pub")
    user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
  }

  resource "openstack_networking_secgroup_v2" "secgroup_1" {
    name = "security_group"
  }

  resource "openstack_networking_secgroup_rule_v2" "ssh_ingress" {
    direction         = "ingress"
    ethertype         = "IPv4"
    protocol          = "tcp"
    port_range_min    = 22
    port_range_max    = 22
    remote_ip_prefix  = "0.0.0.0/0"
    security_group_id = openstack_networking_secgroup_v2.secgroup_1.id
  }

  resource "openstack_networking_secgroup_rule_v2" "icmp_ingress" {
    direction         = "ingress"
    ethertype         = "IPv4"
    protocol          = "icmp"
    remote_ip_prefix  = "0.0.0.0/0"
    security_group_id = openstack_networking_secgroup_v2.secgroup_1.id
  }

  resource "selectel_vpc_public_port_v1" "public_port_1" {
    name               = "public_port"
    security_group_ids = [openstack_networking_secgroup_v2.secgroup_1.id] 
  }

  data "openstack_images_image_v2" "image_1" {
    name        = "Ubuntu 20.04 LTS 64-bit"
    most_recent = true
    visibility  = "public"
  }

  resource "openstack_blockstorage_volume_v3" "volume_1" {
    name                 = "boot-volume-for-server"
    size                 = "5"
    image_id             = data.openstack_images_image_v2.image_1.id
    volume_type          = "fast.ru-6a"
    availability_zone    = "ru-6a"
    enable_online_resize = true

    lifecycle {
      ignore_changes = [image_id]
    }

  }

  resource "openstack_compute_instance_v2" "server_1" {
    name              = "server"
    flavor_id         = "1054"
    key_pair          = selectel_vpc_keypair_v2.keypair_1.name
    availability_zone = "ru-6a"

    network {
      port = selectel_vpc_public_port_v1.public_port_1.id
      uuid = selectel_vpc_public_port_v1.public_port_1.network_id
      name = "network"
    }

    lifecycle {
      ignore_changes = [image_id, availability_zone]
    }

    block_device {
      uuid             = openstack_blockstorage_volume_v3.volume_1.id
      source_type      = "volume"
      destination_type = "volume"
      boot_index       = 0
    }

    vendor_options {
      ignore_resize_confirmation = true
    }
  }

  output "public_ip_address" {
    value = selectel_vpc_public_port_v1.public_port_1.ip_address
  }
  ```
</details>

## 1. Опционально: настроить провайдеры \{#configure-providers}

Если вы [настроили провайдеры](/terraform/configure-terraform-environment/#configure-providers) Selectel и OpenStack, пропустите этот шаг.

<ConfigureProviders />

## 2. Добавить публичный SSH-ключ \{#add-public-ssh-key}

<AddPublicSsh />

## 3. Создать группу безопасности \{#create-security-group}

```hcl
resource "openstack_networking_secgroup_v2" "secgroup_1" {
  name = "security_group"
}

resource "openstack_networking_secgroup_rule_v2" "ssh_ingress" {
  direction         = "ingress"
  ethertype         = "IPv4"
  protocol          = "tcp"
  port_range_min    = 22
  port_range_max    = 22
  remote_ip_prefix  = "0.0.0.0/0"
  security_group_id = openstack_networking_secgroup_v2.secgroup_1.id
}

resource "openstack_networking_secgroup_rule_v2" "icmp_ingress" {
  direction         = "ingress"
  ethertype         = "IPv4"
  protocol          = "icmp"
  remote_ip_prefix  = "0.0.0.0/0"
  security_group_id = openstack_networking_secgroup_v2.secgroup_1.id
}
```

Посмотрите подробное описание ресурсов:

* [openstack\_networking\_secgroup\_v2](/terraform/openstack-provider-reference/networking-neutron/resources/openstack_networking_secgroup_v2/);
* [openstack\_networking\_secgroup\_rule\_v2](/terraform/openstack-provider-reference/networking-neutron/resources/openstack_networking_secgroup_rule_v2/).

## 4. Создать порт с прямым публичным IP-адресом \{#create-port}

```hcl
resource "selectel_vpc_public_port_v1" "public_port_1" {
  name               = "public_port"
  security_group_ids = openstack_networking_secgroup_v2.secgroup_1.id

}
```

Посмотрите подробное описание ресурса [selectel\_vpc\_public\_port\_v1](/terraform/selectel-provider-reference/resources/vpc_public_port_v1/).

## 5. Получить образ \{#get-image}

<GetImage />

## 6. Создать загрузочный сетевой диск \{#create-boot-volume}

<CreateBootVolume />

## 7. Создать облачный сервер \{#create-server}

```hcl
resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = "1054"
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-6a"

  network {
    port = selectel_vpc_public_port_v1.public_port_1.id
    uuid = selectel_vpc_public_port_v1.public_port_1.network_id
    name = "network"
  }

  lifecycle {
    ignore_changes = [image_id, availability_zone]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}
```

Здесь:

* `flavor_id` — ID флейвора. Флейворы соответствуют [конфигурациям облачного сервера](/cloud-servers/create/configurations/) и определяют количество vCPU, RAM и размер локального диска (опционально) сервера.
  Например, `1054` — ID для создания сервера с фиксированной конфигурацией линейки Standard с 4 vCPU, 8 ГБ RAM с выделенными ядрами в пуле ru-6.
  Список доступных флейворов можно посмотреть в подразделе [Список флейворов фиксированной конфигурации во всех пулах](/cloud-servers/create/configurations/#server-flavors-full-list) инструкции [Конфигурации облачных серверов](/cloud-servers/create/configurations/);

* `availability_zone` — [сегмент пула](/infrastructure/locations/#pool), в котором будет создан облачный сервер, например `ru-6a`.
  Список доступных сегментов пула можно посмотреть в инструкции [Матрицы доступности](/infrastructure/product-availability-by-location/);

* в блоке `network`:

  * `name` — имя сети. Можно указать любое произвольное значение, так как сеть будет найдена по параметру `uuid`.

Посмотрите подробное описание ресурса [openstack\_compute\_instance\_v2](/terraform/openstack-provider-reference/compute-nova/resources/openstack_compute_instance_v2/).

## 8. Получить IP-адрес облачного сервера \{#get-ip}

```hcl
output "public_ip_address" {
  value = selectel_vpc_public_port_v1.public_port_1.ip_address
}
```

<Formbricks />