---
title: "Create a MySQL semi-sync cluster via Terraform"
sidebar_label: "Create a MySQL semi-sync cluster"
description: "How to create a MySQL semi-sync cluster with a database"
sidebar_position: 4
---

import Formbricks from '@theme/MDXComponents/Formbricks'
import ConfigureProviders from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/common/configure-providers.mdx'
import ConfigureProvidersConfig from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/common/configure-providers-config.mdx'
import CreateRouter from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/create-router.mdx'
import CreateNetworks from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/create-networks.mdx'
import CreateResourcesAlert from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/common/create-resources-alert.mdx'
import CreateDatabaseMySQL from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/managed-databases/create-database-mysql.mdx'
import CreateUserMySQL from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/managed-databases/create-user-mysql.mdx'
import GrantAccessMySQL from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/managed-databases/grant-access-mysql.mdx'
import Tabs from '@theme/Tabs'
import TabItem from '@theme/TabItem'
import {TabItemLabel} from '@selectel/docux/components'

# Create a MySQL semi-sync cluster via Terraform

<CreateResourcesAlert />

<br />

1. Optional: [configure providers](#configure-providers).
2. [Create a private network and subnet](#create-networks).
3. [Create a cluster](#create-cluster).
4. [Create a user](#create-user).
5. [Create a database](#create-database).
6. [Grant the user access to the database](#grant-access).

## Configuration files \{#config}

<details>
  <summary>Example file for configuring providers</summary>

  <ConfigureProvidersConfig />
</details>

<details>
  <summary>Example file for creating a MySQL semi-sync cluster with a fixed configuration</summary>

  ```hcl
  resource "openstack_networking_network_v2" "network_1" {
    name           = "private-network"
    admin_state_up = "true"
  }

  resource "openstack_networking_subnet_v2" "subnet_1" {
    network_id = openstack_networking_network_v2.network_1.id
    cidr       = "192.168.199.0/24"
  }

  data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
    project_id = selectel_vpc_project_v2.project_1.id
    region     = "ru-9"
    filter {
      engine  = "mysql_native"
      version = "8"
    }
  }

  data "selectel_dbaas_flavor_v1" "flavor_1" {
  project_id = selectel_vpc_project_v2.project_1.id
  region     = "ru-9"
  filter {
    datastore_type_id = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
    fl_size           = "standard"
    vcpus             = 4
    ram               = 16384
    disk              = 128
    }
  }

  resource "selectel_dbaas_mysql_datastore_v1" "datastore_1" {
    name       = "datastore-1"
    project_id = selectel_vpc_project_v2.project_1.id
    region     = "ru-9"
    type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
    subnet_id  = openstack_networking_subnet_v2.subnet_1.id
    node_count = 3
    flavor_id  = data.selectel_dbaas_flavor_v1.flavor_1.flavors[0].id
  }

  resource "selectel_dbaas_user_v1" "user_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
    name         = "user"
    password     = "secret"
  }

  resource "selectel_dbaas_mysql_database_v1" "database_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
    name         = "database_1"
  }

  resource "selectel_dbaas_grant_v1" "grant_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
    database_id  = selectel_dbaas_mysql_database_v1.database_1.id
    user_id      = selectel_dbaas_user_v1.user_1.id
  }

  ```
</details>

<details>
  <summary>Example file for creating a MySQL semi-sync cluster with a custom configuration</summary>

  ```hcl
  resource "openstack_networking_network_v2" "network_1" {
    name           = "private-network"
    admin_state_up = "true"
  }

  resource "openstack_networking_subnet_v2" "subnet_1" {
    network_id = openstack_networking_network_v2.network_1.id
    cidr       = "192.168.199.0/24"
  }

  data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
    project_id = selectel_vpc_project_v2.project_1.id
    region     = "ru-9"
    filter {
      engine  = "mysql_native"
      version = "8"
    }
  }

  resource "selectel_dbaas_mysql_datastore_v1" "datastore_1" {
    name       = "datastore-1"
    project_id = selectel_vpc_project_v2.project_1.id
    region     = "ru-9"
    type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
    subnet_id  = openstack_networking_subnet_v2.subnet_1.id
    node_count = 3
    flavor {
      vcpus = 1
      ram   = 4096
      disk  = 32
    }
  }

  resource "selectel_dbaas_user_v1" "user_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
    name         = "user"
    password     = "secret"
  }

  resource "selectel_dbaas_mysql_database_v1" "database_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
    name         = "database_1"
  }

  resource "selectel_dbaas_grant_v1" "grant_1" {
    project_id   = selectel_vpc_project_v2.project_1.id
    region       = "ru-9"
    datastore_id = selectel_dbaas_mysql_datastore_v1.datastore_1.id
    database_id  = selectel_dbaas_mysql_database_v1.database_1.id
    user_id      = selectel_dbaas_user_v1.user_1.id
  }

  ```
</details>

## 1. Optional: configure providers \{#configure-providers}

If you have [configured the Selectel and OpenStack providers](/terraform/configure-terraform-environment/#configure-providers), skip this step.

<ConfigureProviders />

## 2. Create a private network and subnet \{#create-networks}

<CreateNetworks />

## 3. Create a cluster \{#create-cluster}

<Tabs queryString="create-cluster">
  <TabItem value="fixed" default>
    <TabItemLabel>
      Fixed configuration
    </TabItemLabel>

    ```hcl
    data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      filter {
        engine  = "mysql_native"
        version = "8"
      }
    }

    data "selectel_dbaas_flavor_v1" "flavor_1" {
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      filter {
        datastore_type_id = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
        fl_size           = "standard"
        vcpus             = 4
        ram               = 16384
        disk              = 128
        }
      }


    resource "selectel_dbaas_mysql_datastore_v1" "datastore_1" {
      name       = "datastore-1"
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
      subnet_id  = openstack_networking_subnet_v2.subnet_1.id
      node_count = 3
      flavor_id  = data.selectel_dbaas_flavor_v1.flavor_1.flavors[0].id
    }
    ```

    Where:

    * `region` — pool, e.g. `ru-9`. For a list of available pools, see the [Availability Matrix](/infrastructure/availability-matrix/#managed-databases) guide;
    * `filter` — filter for Managed Databases types:
      * `engine` — type of Managed Databases. For a MySQL semi-sync cluster, specify `mysql_native`;
      * `version` — managed database version. For a list of available versions, see the [Versions and configurations](/managed-databases/mysql-semi-sync/configurations/) guide;
    * `nodes_count` — number of nodes. The maximum number of nodes is 3;
    * `filter` — filter for fixed cluster configurations. For a list of available configurations, see the [Versions and configurations](/managed-databases/mysql-semi-sync/configurations/) guide;
      * `fl_size` — [fixed configuration line](/managed-databases/mysql-semi-sync/configurations/). Available values are `standard` (for Standard, CPU, and Memory lines) and `high_freq` (for the HighFreq line);
      * `vcpus` — number of vCPUs;
      * `ram` — amount of RAM in MB;
      * `disk` — disk size in GB.

    See the detailed description of data sources and resources:

    * [selectel\_dbaas\_datastore\_type\_v1](/terraform/selectel-provider-reference/data-sources/dbaas_datastore_type_v1/);
    * [selectel\_dbaas\_flavor\_v1](/terraform/selectel-provider-reference/data-sources/dbaas_flavor_v1/);
    * [selectel\_dbaas\_mysql\_datastore\_v1](/terraform/selectel-provider-reference/resources/dbaas_mysql_datastore_v1/).
  </TabItem>

  <TabItem value="custom">
    <TabItemLabel>
      Custom configuration
    </TabItemLabel>

    ```hcl
    data "selectel_dbaas_datastore_type_v1" "datastore_type_1" {
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      filter {
        engine  = "mysql_native"
        version = "8"
      }
    }

    resource "selectel_dbaas_mysql_datastore_v1" "datastore_1" {
      name       = "datastore-1"
      project_id = selectel_vpc_project_v2.project_1.id
      region     = "ru-9"
      type_id    = data.selectel_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
      subnet_id  = openstack_networking_subnet_v2.subnet_1.id
      node_count = 3
      flavor {
        vcpus = 1
        ram   = 4096
        disk  = 32
      }
    }
    ```

    Where:

    * `region` — pool, e.g. `ru-9`. For a list of available pools, see the [Availability Matrix](/infrastructure/availability-matrix/#managed-databases) guide;
    * `filter` — filter for Managed Databases types:
      * `engine` — type of Managed Databases. For a MySQL semi-sync cluster, specify `mysql_native`;
      * `version` — managed database version. For a list of available versions, see the [Versions and configurations](/managed-databases/mysql-semi-sync/configurations/) guide;
    * `nodes_count` — number of nodes. The maximum number of nodes is 6;
    * `flavor` — custom cluster configuration. For available custom configuration values, see the [Versions and configurations](/managed-databases/mysql-semi-sync/configurations/) guide:
      * `vcpus` — number of vCPUs;
      * `ram` — amount of RAM in MB;
      * `disk` — disk size in GB.

    See the detailed description of data sources and resources:

    * [selectel\_dbaas\_datastore\_type\_v1](/terraform/selectel-provider-reference/data-sources/dbaas_datastore_type_v1/);
    * [selectel\_dbaas\_flavor\_v1](/terraform/selectel-provider-reference/data-sources/dbaas_flavor_v1/);
    * [selectel\_dbaas\_mysql\_datastore\_v1](/terraform/selectel-provider-reference/resources/dbaas_mysql_datastore_v1/).
  </TabItem>
</Tabs>

## 4. Create a user \{#create-user}

<CreateUserMySQL />

## 5. Create a database \{#create-database}

<CreateDatabaseMySQL />

## 6. Grant the user access to the database \{#grant-access}

<GrantAccessMySQL />

<Formbricks />