Skip to main content

Create several file storages via Terraform

We recommend creating resources sequentially. If you create all resources at the same time, Terraform will take into account the dependencies between resources that you specified in the configuration file. If dependencies are not specified, resources will be created in parallel, which may lead to errors. For example, a resource required to create another resource may not be created yet.


  1. Optional: configure providers.
  2. Create a private network and subnet.
  3. Set variables for file storages.
  4. Configure storage network configuration.
  5. Create file storages.
  6. Configure access rules for file storages.

Configuration files

Example configuration file for providers
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}
Example configuration file for creating three file storages
resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

variable "storages" {
  default = [
    { name = "nfs-storage-1", size = 50, type="basic.ru-3a", proto="NFS", ip = "192.168.199.10" },
    { name = "nfs-storage-2", size = 100, type="fast.ru-3a", proto="NFS", ip = "192.168.199.11" },
    { name = "nfs-storage-3", size = 50, type="universal.ru-3a", proto="CIFS", ip = "192.168.199.12" },
  ]
}

resource "openstack_sharedfilesystem_sharenetwork_v2" "share_network" {
  count             = length(var.storages)
  name              = "share-network-${count.index}"
  neutron_net_id    = openstack_networking_network_v2.network_1.id
  neutron_subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

resource "openstack_sharedfilesystem_share_v2" "share" {
  count            = length(var.storages)
  name             = var.storages[count.index].name
  share_type       = var.storages[count.index].type
  share_proto      = var.storages[count.index].proto
  size             = var.storages[count.index].size
  share_network_id = openstack_sharedfilesystem_sharenetwork_v2.sharenetwork.id
  metadata         = { ip = var.storages[count.index].ip }
}

resource "openstack_sharedfilesystem_share_access_v2" "share_access" {
  count        = length(var.storages)
  access_level = "rw"
  access_to    = "0.0.0.0/0"
  access_type  = "ip"
  share_id     = openstack_sharedfilesystem_share_v2.share[count.index].id
}

1. Optional: configure providers

If you configured the providers for Selectel and OpenStack, skip this step.

  1. Make sure that in the control panel you have created a service user with the member roles in the Account scope and iam.admin.

  2. Create a directory to store configuration files and a separate file with the .tf extension to configure providers.

  3. Add the Selectel and OpenStack providers to the file for provider configuration:

    terraform {
      required_providers {
        selectel  = {
          source  = "selectel/selectel"
          version = "~> 7.1.0"
        }
        openstack = {
          source  = "terraform-provider-openstack/openstack"
          version = "2.1.0"
        }
      }
    }

    Here version is provider versions. You can check the current version in the Selectel documentation (in the Terraform Registry and GitHub) and OpenStack (in the Terraform Registry and GitHub).

    For more information about products, services, and features that can be managed using providers, see the Selectel and OpenStack Providers instructions.

  4. Initialize the Selectel provider:

    provider "selectel" {
      domain_name = "123456"
      username    = "user"
      password    = "password"
      auth_region = "ru-9"
      auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
    }

    Where:

    • domain_name — Selectel account number. You can find it in the control panel in the upper-right corner;
    • username — name of the service user with the member roles in the Account scope and iam.admin. You can find it in the control panel: in the top menu, click IAM → Service Users (the section is available only to the Account Owner and a user with the iam.admin role);
    • password — password of the service user. You can view it when creating the user or change it to a new one;
    • auth_region — pool for authorization in the ru-9 format; do not use pools in the SPB-2 format. The pool for authorization may differ from the pool where you create resources. You can check the list of available pools in the Product Availability by Location instructions.

  5. Create a project:

    resource "selectel_vpc_project_v2" "project_1" {
      name = "project"
    }

    See the detailed description of the selectel_vpc_project_v2 resource.

  6. Create a service user to access the project and assign them the member role in the Project scope:

    resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
      name         = "username"
      password     = "password"
      role {
        role_name  = "member"
        scope      = "project"
        project_id = selectel_vpc_project_v2.project_1.id
      }
    }

    Where:

    • username — username;

    • password — user password. The password must be at least 20 characters long and include at least:

      • one uppercase and one lowercase Latin letter (A-Z, a-z);
      • one digit (0-9);
      • one special character from the ASCII Printable 7-Bit Special Characters list:
        !"#$%&'()*+,-./:;<=>?@[]^_{|}~;

    • project_id — project ID. You can find it in the control panel: in the top menu, click IAM → Projects → in the row of the desired project, click .

    See the detailed description of the selectel_iam_serviceuser_v1 resource.

  7. Initialize the OpenStack provider:

    provider "openstack" {
      auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
      domain_name = "123456"
      tenant_id   = selectel_vpc_project_v2.project_1.id
      user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
      password    = selectel_iam_serviceuser_v1.serviceuser_1.password
      region      = "ru-9"
    }

    Where:

    • domain_name — Selectel account number. You can find it in the control panel in the upper-right corner;
    • region — pool, for example, ru-9. All resources will be created in this pool. You can check the list of available pools in the Product Availability by Location instructions.

  8. If you create resources at the same time as configuring providers, add the depends_on argument for OpenStack resources. For example, for the openstack_networking_network_v2 resource:

    resource "openstack_networking_network_v2" "network_1" {
      name           = "private-network"
      admin_state_up = "true"

      depends_on = [
        selectel_vpc_project_v2.project_1,
        selectel_iam_serviceuser_v1.serviceuser_1
      ]
    }

  9. Optional: if you want to use a mirror, create a separate Terraform CLI configuration file and add the following block to it:

    provider_installation {
      network_mirror {
        url = "https://tf-proxy.selectel.ru/mirror/v1/"
        include = ["registry.terraform.io/*/*"]
      }
      direct {
        exclude = ["registry.terraform.io/*/*"]
      }
    }

    For more information about mirror settings, see the CLI Configuration File instructions in the HashiCorp documentation.

  10. Open the CLI.

  11. Initialize the Terraform configuration in the directory:

    terraform init

  12. Verify that the configuration files are syntactically correct:

    terraform validate

  13. Format the configuration files:

    terraform fmt

  14. Check which resources will be created:

    terraform plan

  15. Apply the changes and create the resources:

    terraform apply

  16. Confirm the creation — enter yes and press Enter. The created resources will appear in the control panel.

  17. If there are not enough quotas to create resources, increase quotas.

2. Create a private network and subnet

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here, cidr is the CIDR of the private subnet, for example, 192.168.199.0/24.

See the detailed resource description:

3. Set variables for file storages

Define a variable with parameters for each file storage you need to create.

variable "storages" {
  default = [
    { name = "nfs-storage-1", size = 50, type="basic.ru-3a", proto="NFS", ip = "192.168.199.10" },
    { name = "nfs-storage-2", size = 100, type="fast.ru-3a", proto="NFS", ip = "192.168.199.11" },
    { name = "nfs-storage-3", size = 50, type="universal.ru-3a", proto="CIFS", ip = "192.168.199.12" },
  ]
}

Where:

  • name — file storage name;
  • size — file storage size in GB, for example 50. Limits: from 50 GB to 50 TB;
  • type — file storage type and pool segment in the format <type>.<pool_segment>, for example basic.ru-9a:
    • <type>
      • basic — Basic HDD type;
      • universal — Universal SSD type;
      • fast — Fast SSD type;
    • <pool_segment> — pool segment in which the file storage will be created, for example ru-9a. The list of available pool segments can be found in the instructions Product availability by location;
  • proto — file storage protocol:
    • NFS — for the NFSv4 protocol;
    • CIFS — for the CIFS SMBv3 protocol;
  • optional: ip — private IP address of the file storage, for example 192.168.199.10. After the storage is created, the IP address cannot be changed.

4. Configure storage networks

For each file storage, a separate openstack_sharedfilesystem_sharenetwork_v2 resource will be automatically created, even if the file storages use the same private network and subnet.

resource "openstack_sharedfilesystem_sharenetwork_v2" "share_network" {
  count             = length(var.storages)
  name              = "share-network-${count.index}"
  neutron_net_id    = openstack_networking_network_v2.network_1.id
  neutron_subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

5. Create file storages

resource "openstack_sharedfilesystem_share_v2" "share" {
  count            = length(var.storages)
  name             = var.storages[count.index].name
  share_type       = var.storages[count.index].type
  share_proto      = var.storages[count.index].proto
  size             = var.storages[count.index].size
  share_network_id = openstack_sharedfilesystem_sharenetwork_v2.share_network[count.index].id
  metadata         = { ip = var.storages[count.index].ip }
}

Where:

  • count — number of file storages to create. The value will be based on the number of file storages that you specified in the variable earlier;
  • share_type — file storage type and pool segment in the format <type>.<pool_segment>, for example basic.ru-9a. The value for each file storage is taken from the variable you set earlier;
  • share_proto — file storage protocol. The value for each file storage is taken from the variable you set earlier:
    • NFS — for the NFSv4 protocol;
    • CIFS — for the CIFS SMBv3 protocol;
  • size — file storage size in GB, for example 50. Limits: from 50 GB to 50 TB. The value for each file storage is taken from the variable you set earlier;
  • optional: metadata = {"ip": "<ip_address>"} — private IP address of the file storage, for example 192.168.199.10. After the storage is created, the IP address cannot be changed. The value for each file storage is taken from the variable you set earlier.

See the detailed description of the openstack_sharedfilesystem_share_v2 resource.

6. Configure access rules for file storages

resource "openstack_sharedfilesystem_share_access_v2" "share_access" {
  count        = length(var.storages)
  access_level = "rw"
  access_to    = "0.0.0.0/0"
  access_type  = "ip"
  share_id     = openstack_sharedfilesystem_share_v2.share[count.index].id
}

Where:

  • count — number of file storages. The value will be based on the number of file storages that you specified in the variable earlier;
  • access_level — access level to the storage, which depends on the protocol:
    • for CIFS SMBv3 — rw (read and write);
    • for NFSv4 — ro (read-only) or rw (read and write);
  • access_to — IP address or CIDR of the private subnet to which access will be granted. For example:
    • 192.168.199.10 — access for an IP address;
    • 192.168.199.0/24 — access for a private subnet range;
    • 0.0.0.0/0 — access for all addresses of the private subnet where the file storages are located. To configure access to file storages for any network client, you can add to the openstack_sharedfilesystem_share_v2 resource the line metadata = {"access_list_allow_all": "true"}.

See the detailed description of the openstack_sharedfilesystem_share_access_v2 resource.