---
title: "Create a custom cloud server with bootable and additional network volumes using Terraform"
sidebar_label: "Create a custom server with bootable and additional network volumes"
sidebar_position: 5
description: "How to create a custom cloud server with a bootable network volume and an additional network volume"
---

import Formbricks from '@theme/MDXComponents/Formbricks'
import ConfigureProviders from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/common/configure-providers.mdx'
import ConfigureProvidersConfig from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/common/configure-providers-config.mdx'
import CreateRouter from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/create-router.mdx'
import CreateNetworks from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/create-networks.mdx'
import AddPublicSsh from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-servers/add-public-ssh-key.mdx'
import CreatePort from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-servers/create-port.mdx'
import GetImage from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-servers/get-image.mdx'
import CreateResourcesAlert from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/common/create-resources-alert.mdx'
import CreateBootVolume from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-servers/create-boot-volume.mdx'
import CreateAdditionalVolume from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-servers/create-additional-volume.mdx'
import CreatePublicIp from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/create-public-ip.mdx'
import AssociateIp from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/associate-ip.mdx'
import GetIp from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/get-ip.mdx'
import CreateFlavorWithNetworkVolume from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-servers/create-flavor-with-network-volume.mdx'

# Create a custom cloud server with bootable and additional network volumes using Terraform

<CreateResourcesAlert />

<br />

1. Optional: [configure providers](#configure-providers).
2. [Add a public SSH key](#add-public-ssh-key).
3. [Create a flavor with a network volume](#create-flavor).
4. [Create a private network and a subnet](#create-networks).
5. [Create a cloud router connected to the Internet](#create-router).
6. [Create a port for the cloud server](#create-port).
7. [Get an image](#get-image).
8. [Create a bootable network volume](#create-boot-volume).
9. [Create an additional network volume](#create-additional-volume).
10. [Create a cloud server](#create-server).
11. [Create a public IP address](#create-public-ip).
12. [Associate the cloud server’s public and private IP addresses](#associate-ip).
13. [Get the cloud server’s IP address](#get-ip).

## Configuration files \{#config}

<details>
  <summary>Example file for configuring providers</summary>

  <ConfigureProvidersConfig />
</details>

<details>
  <summary>Example file for creating a server</summary>

  ```hcl
  resource "selectel_vpc_keypair_v2" "keypair_1" {
    name       = "keypair"
    public_key = file("~/.ssh/id_rsa.pub")
    user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
  }

  resource "openstack_compute_flavor_v2" "flavor_1" {
    name      = "custom-flavor-with-network-volume"
    vcpus     = 2
    ram       = 2048
    disk      = 0
    is_public = false

    lifecycle {
      create_before_destroy = true
    }

  }

  resource "openstack_networking_network_v2" "network_1" {
    name           = "private-network"
    admin_state_up = "true"
  }

  resource "openstack_networking_subnet_v2" "subnet_1" {
    network_id = openstack_networking_network_v2.network_1.id
    cidr       = "192.168.199.0/24"
  }

  data "openstack_networking_network_v2" "external_network_1" {
    external = true
  }

  resource "openstack_networking_router_v2" "router_1" {
    name                = "router"
    external_network_id = data.openstack_networking_network_v2.external_network_1.id
  }

  resource "openstack_networking_router_interface_v2" "router_interface_1" {
    router_id = openstack_networking_router_v2.router_1.id
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }

  resource "openstack_networking_port_v2" "port_1" {
    name       = "port"
    network_id = openstack_networking_network_v2.network_1.id

    fixed_ip {
      subnet_id = openstack_networking_subnet_v2.subnet_1.id
    }
  }

  data "openstack_images_image_v2" "image_1" {
    name        = "Ubuntu 20.04 LTS 64-bit"
    most_recent = true
    visibility  = "public"
  }

  resource "openstack_blockstorage_volume_v3" "volume_1" {
    name                 = "boot-volume-for-server"
    size                 = "5"
    image_id             = data.openstack_images_image_v2.image_1.id
    volume_type          = "fast.ru-9a"
    availability_zone    = "ru-9a"
    enable_online_resize = true

    lifecycle {
      ignore_changes = [image_id]
    }

  }

  resource "openstack_blockstorage_volume_v3" "volume_2" {
    name                 = "additional-volume-for-server"
    size                 = "7"
    volume_type          = "universal.ru-9a"
    availability_zone    = "ru-9a"
    enable_online_resize = true
  }

  resource "openstack_compute_instance_v2" "server_1" {
    name              = "server"
    flavor_id         = openstack_compute_flavor_v2.flavor_1.id
    key_pair          = selectel_vpc_keypair_v2.keypair_1.name
    availability_zone = "ru-9a"

    network {
      port = openstack_networking_port_v2.port_1.id
    }

    lifecycle {
      ignore_changes = [image_id]
    }

    block_device {
      uuid             = openstack_blockstorage_volume_v3.volume_1.id
      source_type      = "volume"
      destination_type = "volume"
      boot_index       = 0
    }

    block_device {
      uuid             = openstack_blockstorage_volume_v3.volume_2.id
      source_type      = "volume"
      destination_type = "volume"
      boot_index       = -1
    }

    vendor_options {
      ignore_resize_confirmation = true
    }
  }

  resource "openstack_networking_floatingip_v2" "floatingip_1" {
    pool = "external-network"
  }

  resource "openstack_networking_floatingip_associate_v2" "association_1" {
    port_id     = openstack_networking_port_v2.port_1.id
    floating_ip = openstack_networking_floatingip_v2.floatingip_1.address
  }

  output "public_ip_address" {
    value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
  }
  ```
</details>

## 1. Optional: configure providers \{#configure-providers}

If you have already configured the Selectel and OpenStack providers, skip this step.

<ConfigureProviders />

## 2. Add a public SSH key \{#add-public-ssh-key}

<AddPublicSsh />

## 3. Create a flavor with a network volume \{#create-flavor}

<CreateFlavorWithNetworkVolume />

## 4. Create a private network and a subnet \{#create-networks}

<CreateNetworks />

## 5. Create a cloud router connected to the Internet \{#create-router}

<CreateRouter />

## 6. Create a port for the cloud server \{#create-port}

<CreatePort />

## 7. Get an image \{#get-image}

<GetImage />

## 8. Create a bootable network volume \{#create-boot-volume}

<CreateBootVolume />

## 9. Create an additional network volume \{#create-additional-volume}

<CreateAdditionalVolume />

## 10. Create a cloud server \{#create-server}

```hcl
resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = openstack_compute_flavor_v2.flavor_1.id
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_2.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = -1
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}
```

Here `availability_zone` — [pool segment](/infrastructure/locations/#pool) where the cloud server will be created, e.g. `ru-9a`. A list of available pool segments can be viewed in the [Availability Matrix](/infrastructure/availability-matrix/).

See the detailed resource description for [openstack\_compute\_instance\_v2](/terraform/openstack-provider-reference/compute-nova/resources/openstack_compute_instance_v2/).

## 11. Create a public IP address \{#create-public-ip}

<CreatePublicIp />

## 12. Associate the cloud server’s public and private IP addresses \{#associate-ip}

<AssociateIp />

## 13. Get the cloud server’s IP address \{#get-ip}

<GetIp />

<Formbricks />