---
title: "Create a cloud load balancer via Terraform"
sidebar_label: "Create a load balancer"
sidebar_position: 1
description: "How to create a cloud load balancer with the Advanced type and redundancy"
---

import Formbricks from '@theme/MDXComponents/Formbricks'
import ConfigureProviders from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/common/configure-providers.mdx'
import ConfigureProvidersConfig from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/common/configure-providers-config.mdx'
import CreateRouter from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/create-router.mdx'
import CreateNetworks from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/create-networks.mdx'
import CreateBalancer from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-load-balancers/create-balancer.mdx'
import CreateRule from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-load-balancers/create-rule.mdx'
import AddServerToTargetGroup from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-load-balancers/add-server-to-target-group.mdx'
import CreateAvailabilityCheck from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-load-balancers/create-availability-check.mdx'
import CreateTargetGroup from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-load-balancers/create-target-group.mdx'
import CreateResourcesAlert from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/common/create-resources-alert.mdx'
import GetIp from '@site/i18n/en/docusaurus-plugin-content-docs-terraform/current/_partials/cloud-networks/get-ip.mdx'

# Create a cloud load balancer via Terraform

<CreateResourcesAlert />

<br />

1. Optional: [configure the providers](#configure-providers).
2. [Create a private network and a subnet](#create-networks).
3. [Create a cloud router connected to the internet](#create-router).
4. [Create a cloud load balancer](#create-load-balancer).
5. [Create a rule](#create-rule).
6. [Create a target group](#create-target-group).
7. [Add a server to the target group](#add-server-to-target-group).
8. [Create an availability check](#create-availability-check).
9. [Create a public IP address and connect it to the load balancer](#create-public-ip).
10. [Get the load balancer IP address](#get-ip).

## Configuration files \{#config}

<details>
  <summary>Example file for configuring providers</summary>

  <ConfigureProvidersConfig />
</details>

<details>
  <summary>Example file for creating a load balancer</summary>

  ```hcl
  resource "openstack_networking_network_v2" "network_1" {
    name           = "private-network"
    admin_state_up = "true"
  }

  resource "openstack_networking_subnet_v2" "subnet_1" {
    name       = "private-subnet"
    network_id = openstack_networking_network_v2.network_1.id
    cidr       = "192.168.199.0/24"
  }

  data "openstack_networking_network_v2" "external_network_1" {
    external = true
  }

  resource "openstack_networking_router_v2" "router_1" {
    name                = "router"
    external_network_id = data.openstack_networking_network_v2.external_network_1.id
  }

  resource "openstack_networking_router_interface_v2" "router_interface_1" {
    router_id = openstack_networking_router_v2.router_1.id
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }

  resource "openstack_lb_loadbalancer_v2" "load_balancer_1" {
    name          = "load-balancer"
    vip_subnet_id = openstack_networking_subnet_v2.subnet_1.id
    flavor_id     = "ac18763b-1fc5-457d-9fa7-b0d339ffb336"
  }

  resource "openstack_lb_listener_v2" "listener_1" {
    name            = "listener"
    protocol        = "TCP"
    protocol_port   = "80"
    loadbalancer_id = openstack_lb_loadbalancer_v2.load_balancer_1.id
  }

  resource "openstack_lb_pool_v2" "pool_1" {
    name        = "pool"
    protocol    = "PROXY"
    lb_method   = "ROUND_ROBIN"
    listener_id = openstack_lb_listener_v2.listener_1.id
  }

  resource "openstack_lb_member_v2" "member_1" {
    name          = "member"
    subnet_id     = openstack_networking_subnet_v2.subnet_1.id
    pool_id       = openstack_lb_pool_v2.pool_1.id
    address       = "192.168.199.4"
    protocol_port = "80"
  }

  resource "openstack_lb_monitor_v2" "monitor_1" {
    name        = "monitor"
    pool_id     = openstack_lb_pool_v2.pool_1.id
    type        = "HTTP"
    delay       = "10"
    timeout     = "4"
    max_retries = "5"
  }

  resource "openstack_networking_floatingip_v2" "floatingip_1" {
    pool    = "external-network"
    port_id = openstack_lb_loadbalancer_v2.load_balancer_1.vip_port_id
  }

  output "public_ip_address" {
    value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
  }
  ```
</details>

## 1. Optional: configure providers \{#configure-providers}

If you have [configured the Selectel and OpenStack providers](/terraform/configure-terraform-environment/#configure-providers), skip this step.

<ConfigureProviders />

## 2. Create a private network and a subnet \{#create-networks}

<CreateNetworks />

## 3. Create a cloud router connected to the internet \{#create-router}

<CreateRouter />

## 4. Create a cloud load balancer \{#create-load-balancer}

<CreateBalancer />

## 5. Create a rule \{#create-rule}

<CreateRule />

## 6. Create a target group \{#create-target-group}

<CreateTargetGroup />

## 7. Add a server to the target group \{#add-server-to-target-group}

<AddServerToTargetGroup />

## 8. Create an availability check \{#create-availability-check}

<CreateAvailabilityCheck />

## 9. Create a public IP address and connect it to the load balancer \{#create-public-ip}

A public IP address will be connected to the load balancer port and associated with a private IP.

```hcl
resource "openstack_networking_floatingip_v2" "floatingip_1" {
  pool    = "external-network"
  port_id = openstack_lb_loadbalancer_v2.load_balancer_1.vip_port_id
}
```

See the detailed resource description for [openstack\_networking\_floatingip\_v2](/terraform/openstack-provider-reference/networking-neutron/resources/openstack_networking_floatingip_v2/).

## 10. Get the load balancer IP address \{#get-ip}

<GetIp />

<Formbricks />